Q:Nicer than: Function[x,MapAt[Im,x,2]]/@data
- To: mathgroup at smc.vnet.net
- Subject: [mg5466] [mg5389] Q:Nicer than: Function[x,MapAt[Im,x,2]]/@data
- From: Allan Hayes <hay at haystack>
- Date: Sat, 7 Dec 1996 00:26:47 -0500
- Sender: owner-wri-mathgroup at wolfram.com
rommel at bc.edu
[mg5389] Q:Nicer than: Function[x,MapAt[Im,x,2]]/@data
writes
>>>>>>
I want to ListPlot the imaginary part of data:
data={{x0,z0},{x1,z1},{x2,z2}}
The x? are real, the z? complex.
My simple but ugly solution was
Transpose[{Transpose[data][[1]],Im[Transpose[data][[2]]]}]
after reading a little I came to the shorter
Function[x,MapAt[Im,x,2]]/@data
Is there a nicer way to do it?
<<<<<<
Some Experiments:
lst = Table[{Random[],Random[]+I Random[]},{2000}];
Function[x,MapAt[Im,x,2]]/@lst;//Timing (*your "shorter" one*)
{1.25 Second, Null}
MapAt[Im,#,2]&/@lst;//Timing (*faster function*)
{0.7 Second, Null}
Apply[{#,Im[#2]}&,lst,1];//Timing (*use Apply*)
{0.466667 Second, Null}
lst/.Complex[x_,y_]:>y;//Timing (*pattern matching*)
{0.483333 Second, Null}
lst/.{a_,Complex[x_,y_]}:>{a,y};//Timing (*help matching*)
{0.383333 Second, Null}
MapAt[Im,Transpose[lst],{2}]//Transpose;//Timing (*your "ugly" one*)
{0.3 Second, Null}
MapAt[Im,Thread[lst],{2}]//Thread;//Timing (*Thread faster
than Transpose*)
{0.25 Second, Null}
Allan Hayes
hay at haystack.demon.co.uk
http://www.haystack.demon.co.uk