Re: Boundary Value Problem
- To: mathgroup at smc.vnet.net
- Subject: [mg6910] Re: Boundary Value Problem
- From: Stephen P Luttrell <luttrell at signal.dra.hmg.gb>
- Date: Fri, 25 Apr 1997 14:00:40 -0400 (EDT)
- Organization: Defence Research Agency
- Sender: owner-wri-mathgroup at wolfram.com
>
> y'''''[x]+y[x]==0
>
> Conditions
> y[0]==0
> y'[0]==7
>
> y[1]==1
> y'[1]==10
> y''[1]=5
>
The solution to this problem that I posted earlier was flawed
(it was rubbish, to be honest!).
I can't get a solution to come out by feeding DSolve with the
differential
equation plus its boundary conditions.
However, I can obtain a solution as follows:
1. Solve the differential equation without boundary conditions:
soln=DSolve[{y'''''[x]+y[x]==0},y[x],x]
which gives:
{{y[x] -> C[1]/E^x + E^((-1)^(1/5)*x)*C[2] +
C[3]/E^(-(-(-1)^(2/5)*x)) + E^((-1)^(3/5)*x)*C[4] +
C[5]/E^(-(-(-1)^(4/5)*x))}}
2. Define a function which implements the solution without boundary
conditions:
y[x_] := C[1]/E^x + E^((-1)^(1/5)*x)*C[2] +
C[3]/E^(-(-(-1)^(2/5)*x)) + E^((-1)^(3/5)*x)*C[4] +
C[5]/E^(-(-(-1)^(4/5)*x))
3. Solve for the (numerical values of the) constants:
const = Chop[Solve[N[{y[0] == 0, Derivative[1][y][0] == 7,
y[1] == 1, Derivative[1][y][1] == 10,
Derivative[1][Derivative[1][y]][1] == 5}],
{C[1], C[2], C[3], C[4], C[5]}]]
which gives:
{{C[1] -> -191.2756607271927,
C[2] -> 57.89644611472424 + 9.823539039817276*I,
C[3] -> 37.74138424887295 - 127.7949066168243*I,
C[4] -> 37.74138424887115 + 127.7949066168247*I,
C[5] -> 57.8964461147244 - 9.82353903981644*I}}
4. Substitute the constants into the solution:
Chop[ComplexExpand[y[x] /. const[[1]]]]
which gives:
-191.2756607271927/E^x + 115.7928922294486*E^(1/4*(1 + Sqrt[5])*x)*
Cos[1/2*Sqrt[1/2*(5 - Sqrt[5])]*x] +
75.4827684977441*E^(1/4*(1 - Sqrt[5])*x)*
Cos[1/2*Sqrt[1/2*(5 + Sqrt[5])]*x] -
19.64707807963371*E^(1/4*(1 + Sqrt[5])*x)*
Sin[1/2*Sqrt[1/2*(5 - Sqrt[5])]*x] -
255.5898132336491*E^(1/4*(1 - Sqrt[5])*x)*
Sin[1/2*Sqrt[1/2*(5 + Sqrt[5])]*x]
5. Define a function which implements the solution with boundary
conditions:
z[x_] := -191.2756607271927/E^x +
115.7928922294486*E^(1/4*(1 + Sqrt[5])*x)*
Cos[1/2*Sqrt[1/2*(5 - Sqrt[5])]*x] +
75.4827684977441*E^(1/4*(1 - Sqrt[5])*x)*
Cos[1/2*Sqrt[1/2*(5 + Sqrt[5])]*x] -
19.64707807963371*E^(1/4*(1 + Sqrt[5])*x)*
Sin[1/2*Sqrt[1/2*(5 - Sqrt[5])]*x] -
255.5898132336491*E^(1/4*(1 - Sqrt[5])*x)*
Sin[1/2*Sqrt[1/2*(5 + Sqrt[5])]*x]
6. Verify that this solution satisfies all of the required conditions:
Chop[{Derivative[1][Derivative[1][Derivative[1][Derivative[1][
Derivative[1][z]]]]][x] + z[x], z[0], Derivative[1][z][0],
z[1], Derivative[1][z][1], Derivative[1][Derivative[1][z]][1]}]
which gives:
{0, 0, 7., 1.000000000000028, 9.999999999999989, 5.}
This is pretty accurate.
==================================================================================
Dr Stephen P Luttrell luttrell at signal.dra.hmg.gb
Adaptive Systems Theory 01684-894046 (phone)
Room EX21, Defence Research Agency 01684-894384 (fax)
Malvern, Worcs, WR14 3PS, U.K.
http://www.dra.hmg.gb/cis5pip/Welcome.html