Re: WEIBULL DISTRIBUTION
- To: mathgroup@smc.vnet.net
- Subject: [mg11851] Re: WEIBULL DISTRIBUTION
- From: Bob Hanlon <BobHanlon@aol.com>
- Date: Wed, 1 Apr 1998 00:35:54 -0500
In a message dated 3/31/98 4:42:21 PM, Simona Bignami wrote:
>I've read the message you sent on 1 January 1997 about Weibull distribution.
>I'm working with Weibull distribution and I would like to fit data with a
>THREE-PARAMETERS Weibull distribution.
>How can accomplish this on Mathematica 3.0?
Needs["Statistics`ContinuousDistributions`"]
PDF[WeibullDistribution[alpha, beta], x]
(alpha*x^(-1 + alpha))/(beta^alpha*E^(x/beta)^alpha)
Domain[WeibullDistribution[alpha, beta]]
Interval[{0, Infinity}]
Mean[WeibullDistribution[alpha, beta]]
beta*Gamma[1 + alpha^(-1)]
I do not know what specific generalization you are interested in to
obtain a three-parameter distribution. However, one possible
generalization would be a probability density of the form
Exp[-(x/beta)^alpha]*x^(gamma - 1);
To find the normalization factor, the integral of the probability
density must
be one.
PowerExpand[Integrate[Exp[-(x/beta)^alpha]*x^(gamma - 1), {x, 0,
Infinity},
Assumptions -> {Re[alpha] > 0, Re[(1/beta)^alpha] > 0}]]
(beta^gamma*Gamma[gamma/alpha])/alpha
Therefor, the probability density is given by
f[alpha_, beta_, gamma_, x_] :=
(alpha*Exp[-(x/beta)^alpha]*x^(gamma -
1))/(beta^gamma*Gamma[gamma/alpha])
PowerExpand[Integrate[f[alpha, beta, gamma, x], {x, 0, Infinity},
Assumptions -> {Re[alpha] > 0, Re[(1/beta)^alpha] > 0}]]
1
This clearly reduces to the two-parameter form when gamma equals alpha.
The mean is given by
PowerExpand[Integrate[x*f[alpha, beta, gamma, x], {x, 0, Infinity},
Assumptions -> {Re[alpha] > 0, Re[(1/beta)^alpha] > 0}]]
(beta*Gamma[(1 + gamma)/alpha])/Gamma[gamma/alpha]
To find the estimated values of the parameters (alpha, beta, gamma) for
a given set of data, use the method of maximum likelihood (maximize
the likelihood function -- see whatever books on advanced statistics
which you have available).
Bob Hanlon