MathGroup Archive 1998

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Conic Sections and Quadric Surfaces



One approach using Mathematica:

pts = {{-1,0},{0,1},{2,2},{1,-1},{0,-3}};

eqn = a x^2 + b x y + c y^2 + d x + e y + f == 0;

The substitution rules for the given points  are

subs = {x -> #[[1]], y -> #[[2]]}& /@ pts

{{x -> -1, y -> 0}, {x -> 0, y -> 1}, {x -> 2, y -> 2}, {x -> 1, y ->
-1}, {x -> 0, y -> -3}}

Solving for the first five variables in terms of the sixth variable

soln = Solve[eqn /. subs, {a,b,c,d,e}]

{{a -> (-29*f)/42, b -> (20*f)/21, c -> -f/3, d -> (13*f)/42, e ->
(-2*f)/3}}

Substituting this solution into the original equation

eqn2 = eqn /. soln

{f + (13*f*x)/42 - (29*f*x^2)/42 - (2*f*y)/3 + (20*f*x*y)/21 - (f*y^2)/3
== 0}

Consequently, either f=0 or

theEqn = eqn2 /. f -> 42

{42 + 13*x - 29*x^2 - 28*y + 40*x*y - 14*y^2 == 0}

Note that any value of f other than zero gives an equivalent equation.

To plot the equation, the standard add-on package ImplicitPlot is used:

Needs["Graphics`ImplicitPlot`"]

ImplicitPlot[theEqn, {x, -4, 3}, {y, -4, 3}];


Bob Hanlon

FORWARDED MESSAGE:

Dear Sir:

Ref: Introduction to Linear Algebra- 4th ed. Johnson,Riess and Arnold
(page 35)

Find the equation of the conic section passing through the five points 
(-1,0),(0,1),(2,2),(1,-1), (0,-3). Display the graph of the conic.

When I try to set up the augmented matrix I get two (2) indeterminate
rows which prevents my proceeding with the method outlined in the
textbook Linear Algebra with Mathematica by E. Johnson page 58 to 59.
How can  I get around this?  The equation to satisfy (an ellipse) is 
ax^2 + bxy + cy^2 + dx + ey + f = 0.  Is there some other technique I
can use to find the equation given several points?

I am presently playing around with Fit[ data,{etc}] but I only know how
to fit quadratics. Thank you in advance.

Manuel Avalos



  • Prev by Date: Re: Re: Conic Sections and Quadric Surfaces
  • Next by Date: Re: A Bug in Flatten?
  • Prev by thread: Re: Re: Conic Sections and Quadric Surfaces
  • Next by thread: Mathematica frustrations...