Re: [Q] Solve?

• To: mathgroup at smc.vnet.net
• Subject: [mg23410] Re: [mg23408] [Q] Solve?
• From: Andrzej Kozlowski <andrzej at tuins.ac.jp>
• Date: Sun, 7 May 2000 21:17:57 -0400 (EDT)
• Sender: owner-wri-mathgroup at wolfram.com

```on 00.5.7 8:14 AM, James at research at proton.csl.uiuc.edu wrote:

>
>
> Hi!
>
> I come across a problem that I don't understand.
> I generate systems of equations
> and try to solve them using mathematica.
> For example,
>
> ---------------------------------------------------------------
> In[1]= Solve[((4/2)*( 1.50*z+ 2.00)+(4-4/2)*
> Sqrt[( 1.50*z+ 0.00)^2+ 4.00]) +
> ((4/2)*( 1.50*z+ 2.00)+(4-4/2)*
> Sqrt[( 1.50*z+ 0.00)^2+ 4.00])- 8.10*z==0, z]
>
> Out[1]= {}
> ---------------------------------------------------------------
>
> But mathematica can't solve it, simply returing empty.
> This equation can be solved, though, as you see.
> I restarted mathematica to run again, but it doesn't help.
>
>
> The weird thing is some equations are solved, like the below.
> ---------------------------------------------------------------
> In[2]= Solve[((4/2)*( 1.50*z+ 2.00)+(2-4/2)*
> Sqrt[( 1.50*z+ 0.00)^2+ 4.00]) +
> ((4/2)*( 1.50*z+ 2.00)+(3-4/2)*
> Sqrt[( 1.50*z+ 0.00)^2+ 4.00])- 8.10*z==0, z]
>
> Out[2]= {{z->13.4976}}
> ---------------------------------------------------------------
>
> What's wrong with it and how can I solve it?
> I need to use mathematica, because the number of the systems
> of equations are large.
> (Please disregard any redundunt terms in the equations..
> they are generated by a program.)
> With that, when does mathematica return '{}' as an answer?
> Thank you.
>
>
> --- James, newbie in mathematica.
>
>
But Mathematica is completely right: there are no solutions. If you do not
believe it, let's do this "by hand".

After simplification your equation becomes:

In[1]:=
eq = ((4/2)*(1.50*z + 2.00) + (4 - 4/2)*
Sqrt[(1.50*z + 0.00)^2 + 4.00]) + ((4/2)*(1.50*z + 2.00) + (4
-
4/2)*Sqrt[(1.50*z + 0.00)^2 + 4.00]) - 8.10*z == 0 //
FullSimplify

Out[1]=
2
8. + 4 Sqrt[4. + 2.25 z ] == 2.1 z

Let's move the 8 to the RHS:

In[2]:=
% /. Equal[a_ + b_?NumericQ, c_] -> Equal[a, c - b]

Out[2]=
2
4 Sqrt[4. + 2.25 z ] == -8. + 2.1 z

Now square both sides and expand:

In[3]:=
Thread[#^2 &[%], Equal] // ExpandAll

Out[3]=
2                         2
64. + 36. z  == 64. - 33.6 z + 4.41 z

Now solve the equation we got:

In[4]:=
Solve[%, z]

Out[4]=
{{z -> -1.06363}, {z -> 0.}}

Now check if the solutions satisfy the original equation:

In[5]:=
eq /. %

Out[5]=
{False, False}

In other words we only got "parasite" solutions. There are no genuine
solutions at all! If you wanted to see the parasite solutions Mathematica
could have given them in one go:

In[6]:=
Solve[eq, VerifySolutions -> False]

Out[6]=
{{z -> -1.06363}, {z -> 0.}}

Your other equation of course does have a solution and Mathematica correctly
finds it.
--
Andrzej Kozlowski
Toyama International University
Toyama, Japan
http://sigma.tuins.ac.jp/

```

• Prev by Date: Can FindMinimum solve boundary value problems?
• Next by Date: Re: [Q] Solve?
• Previous by thread: Re: [Q] Solve?
• Next by thread: Re: [Q] Solve?