RE: ParametricPlot Question
- To: mathgroup at smc.vnet.net
- Subject: [mg37142] RE: [mg37135] ParametricPlot Question
- From: "David Park" <djmp at earthlink.net>
- Date: Sun, 13 Oct 2002 05:56:23 -0400 (EDT)
- Sender: owner-wri-mathgroup at wolfram.com
Charles,
One method is to use Epilog as follows. For simplicity I define the
parametrization of the curve, the list of t values and the list of
associated points. It is also nice to add some color to the plot.
Needs["Graphics`Colors`"]
curve[t_] := {Sin[t], Cos[t]}
tvals = Pi/4Range[0, 7];
pts = curve /@ tvals;
ParametricPlot[Evaluate[curve[t]], {t, 0, 2Pi},
PlotStyle -> Blue,
Epilog -> {Black, AbsolutePointSize[5], Point /@ pts,
MapThread[Text[#1, 1.1 #2] &, {tvals, pts}]},
Axes -> None,
AspectRatio -> Automatic,
PlotRange -> All,
Background -> Linen,
ImageSize -> 430];
If you use the DrawGraphics package at my web site, this can be done
slightly easier, without using PlotStyle or Epilog. ParametricDraw just
extracts the graphics primitives, actually the Line, from ParametricPlot
without a side plot. Then we can just combine it with the Point and Text
primitives. Draw2D is a shortcut for Show[Graphics[...],opts];
Needs["DrawGraphics`DrawingMaster`"]
Draw2D[
{Blue, ParametricDraw[Evaluate[curve[t]], {t, 0, 2Pi}],
Black, AbsolutePointSize[5],
Point /@ pts,
MapThread[Text[#1, 1.1 #2] &, {tvals, pts}]},
AspectRatio -> Automatic,
Background -> Linen,
ImageSize -> 430];
David Park
djmp at earthlink.net
http://home.earthlink.net/~djmp/
From: Charles Morgan [mailto:charlesmorgan at attbi.com]
To: mathgroup at smc.vnet.net
I would like to mark representative samples of t on a parametric plot,
where t is the third parameter. For example, how could I mark the 8
values t=0, t=Pi/4, ..., t=7Pi/4 on the plot generated by:
ParametricPlot[{Sin[t], Cos[t]}, {t, 0, 2Pi}]
Thanks