Re: complex analysis problem in mathematica 3.0
- To: mathgroup at smc.vnet.net
- Subject: [mg48473] Re: [mg48459] complex analysis problem in mathematica 3.0
- From: Bob Hanlon <hanlonr at cox.net>
- Date: Tue, 1 Jun 2004 03:02:49 -0400 (EDT)
- Reply-to: hanlonr at cox.net
- Sender: owner-wri-mathgroup at wolfram.com
Hs[s_] = 1/(s^3+2s^2+2s+1);
Hs[I*w]
1/((-I)*w^3 - 2*w^2 + 2*I*w + 1)
ComplexExpand[%]
-((2*w^2)/((1 - 2*w^2)^2 + (2*w - w^3)^2)) +
I*(w^3/((1 - 2*w^2)^2 + (2*w - w^3)^2) -
(2*w)/((1 - 2*w^2)^2 + (2*w - w^3)^2)) +
1/((1 - 2*w^2)^2 + (2*w - w^3)^2)
Collecting the Real terms
FullSimplify[%, ExcludedForms->I*_]
(1 - 2*w^2)/(w^6 + 1) +
I*(w^3/((1 - 2*w^2)^2 + (2*w - w^3)^2) -
(2*w)/((1 - 2*w^2)^2 + (2*w - w^3)^2))
Collecting the imaginary terms
Together /@ %
(1 - 2*w^2)/(w^6 + 1) + (I*(w^3 - 2*w))/(w^6 + 1)
This can all be done in one step
Hw[w_] = Together /@ FullSimplify[ComplexExpand[Hs[I*w]], ExcludedForms-
>I*_];
Verifying
Hs[I*w] == Hw[w] // Simplify
True
>
> From: BranasMan <branasREmoVe at mail.inet.hr>
To: mathgroup at smc.vnet.net
> Date: 2004/05/31 Mon AM 12:13:36 EDT
> To: mathgroup at smc.vnet.net
> Subject: [mg48473] [mg48459] complex analysis problem in mathematica 3.0
>
> i have a complex function:
>
> H(s)=1 / (s^3 + 2s^2 + 2s + 1)
>
> whan i replace "s" with j*w (j=sqrt(-1)) i get:
>
> H=1 / (1 + j2w -2w^2 - jw^3)
>
> i would like to get that function in shape of :
> H=something + j*something_else i.e. the complex
> and real part apart.
>
> i played with Re and Im,but it seems that the fact that
> "w" is a variable confuses mathematica?!
>
> i would reeeealy appreciate any help,and maybe perhaps some
> links for me to learn to use mathematica better.
>
Bob Hanlon
Chantilly, VA