Re: Integrating Feynman integrals in mathematica
- To: mathgroup at smc.vnet.net
- Subject: [mg51169] Re: Integrating Feynman integrals in mathematica
- From: Paul Abbott <paul at physics.uwa.edu.au>
- Date: Thu, 7 Oct 2004 05:25:47 -0400 (EDT)
- Organization: The University of Western Australia
- References: <ciu5iv$81d$1@smc.vnet.net>
- Sender: owner-wri-mathgroup at wolfram.com
In article <ciu5iv$81d$1 at smc.vnet.net>, pabird at supanet.com (Xman)
wrote:
> I am trying to find an explicit form of the following 4-dimensional
> fourier transforms. Can anyone help? ( x and k are 4 dimensional
> vectors) They are from physics.
>
> 1)
>
> f(x) =Intregral[ e^(i x.k) / (k.k -m^2) ]dk^4
Shouldn't this be k.k + m^2 (to agree with your equation for f below)?
> 2)
>
> g(x)=Intregral[ e^(i x.k) / (k.k -m^2)^2 ]dk^4
>
> I know that the first is of the form:
>
> f(x) = 1/|x.x| + log|x.x| * P((m^2/4) |x.x|) + Q((m^2/4) |x.x|)
>
> (when m=0 this becomes 1/|x.x|)
>
> Where P and Q stand for infinite polynomial series and that I think
> P(y) = Sum( y^n /(n!(n+1)!) ,y=0..infinity )
Apart from the error in syntax and summation index, Mathematica can
compute this sum in closed form. Try
Sum[y^n/(n! (n+1)!),{n,0,Infinity}]
> and that in the second one
> g(x) = log|x.x| * R((m^2/4) |x.x|) + S((m^2/4) |x.x|)
>
> (when m=0 this becomes log|x.x|)
>
> where R(y) = Sum( y^n /(n!n!) ,y=0..infinity )
and this one too.
> But the functions Q and S are more difficult to find.
> Plus does anyone know if the series P and R (=P') or Q and S can be
> written in terms of simple functions?
>
> It may help to know that f and g satisfy the following 4 dimensional
> wave equations:
>
> ( d/dx . d/dx - m^2) f(x) = delta(x) (=0 for x=/=0)
> ( d/dx . d/dx - m^2)^2 g(x) = delta(x) (=0 for x=/=0)
>
> I am particularly interested in g(x).
As pointed out by Steve Luttrell, if you can compute f(x), you know g(x)
by parametric differentiation. Let me indicate how you can get
Mathematica to compute the integral over 4 dimensional space of the
integrand
h[x_][k_] := Exp[I x.k]/(k.k + m^2)
(related to yours) in closed form. As you have observed, the integral
only depends on the length of the 4 dimensional vector x. Call this r.
Let p denote the magnitude of the vector k. If you express k in
hyperspherical co-ordinates, say
k = p {Sin[a]Sin[b]Sin[c],Sin[a]Sin[b]Cos[c],Sin[a]Cos[b],Cos[a]}
where p is in [0,Infinity), c is in [0,2Pi], and a and b are in [0,Pi],
then the volume element reads
dk^4 = p^3 dp Sin[a]^2 da Sin[b] db dc
Now, because the angular part of the k integral is over all possible
orientations of the vector k, you can choose an _arbitrary_ orientation
for x (this is why the integral only depends on r). The choice resulting
in the simplest integrand is
x = {0,0,0,r}
so that the integrand becomes
Exp[I p r Cos[a]]/(p^2 + m^2)
where a is the angle between x and k. The integrals over b and c are now
trivial,
Integrate[Sin[b], {b,0,Pi},{c,0,2Pi}]
leading to an overall multiplicative factor of 4 Pi.
You are left with the following computation: first compute the integral
over a,
Assuming[r > 0 && m > 0 && p > 0,
4 Pi Integrate[Exp[I p r Cos[a]]/(p^2 + m^2) Sin[a]^2, {a, 0, Pi}]]
followed by the integral over p
Assuming[r > 0 && m > 0, Integrate[% p^3, {p, 0, Infinity}]]
which evaluates to the very simple closed-form result
4 m Pi^2 BesselK[1, m r]/r
When m = 0, this reduces to 4 Pi^2 / r^2 as you can see from the
following series expansion:
4 m Pi^2 BesselK[1, m r]/r + O[m]
Expanding the result as a series in r, one obtains
4 m Pi^2 (1/r^2 + (m BesselI[1, m r]/r) Log[r] + ...)
exactly of the form you write above (check this by series expansion of
the BesselI[1, m r] function).
The integral with (p^2 + m^2)^2 in the denominator is even simpler.
Using parametric differentiation, you obtain
2 Pi^2 BesselK[0, m r]
Cheers,
Paul
--
Paul Abbott Phone: +61 8 6488 2734
School of Physics, M013 Fax: +61 8 6488 1014
The University of Western Australia (CRICOS Provider No 00126G)
35 Stirling Highway
Crawley WA 6009 mailto:paul at physics.uwa.edu.au
AUSTRALIA http://physics.uwa.edu.au/~paul