Re: How to simplify to a result that is real
- To: mathgroup at smc.vnet.net
- Subject: [mg50742] Re: [mg50679] How to simplify to a result that is real
- From: DrBob <drbob at bigfoot.com>
- Date: Sat, 18 Sep 2004 05:49:17 -0400 (EDT)
- References: <200409170515.BAA11699@smc.vnet.net>
- Reply-to: drbob at bigfoot.com
- Sender: owner-wri-mathgroup at wolfram.com
This may not help you, but here's a reduction of the result to a clearly real-valued expression.
First, look at this expansion of the Log of a Complex number:
ComplexExpand[Log[x + I*y]]
First[%]
I*Arg[x + I*y] + (1/2)*Log[x^2 + y^2]
I*Arg[x + I*y]
Later I'll apply this to a complex number whose Norm is one, so that Log[x^2 + y^2]==0.
Here's the Integrate output:
one = Integrate[1/(1 + e*Cos[t]), {t, 0, a}, Assumptions -> {-1 < e < 1, 0 < a < Pi}]
-((1/Sqrt[1 - e^2])*(I*Log[Sqrt[1 - e^2] - I*(-1 + e)*Tan[
a/2]])) + (1/Sqrt[1 - e^2])*(I*Log[Sqrt[1 - e^2] + I*(-1 + e)*Tan[a/2]])
Next I factor Sqrt[1 - e^2]/I out of the expression. Later I'll undo this.
two = (#1*(Sqrt[1 - e^2]/I) & ) /@ one
-Log[Sqrt[1 - e^2] - I*(-1 + e)*Tan[a/2]] + Log[Sqrt[1 - e^2] + I*(-1 + e)*Tan[a/2]]
Transform the difference of Logs as follows:
three = two /. -Log[x_] + Log[y_] -> Log[x/y]
Log[(Sqrt[1 - e^2] - I*(-1 + e)*Tan[a/2])/
(Sqrt[1 - e^2] + I*(-1 + e)*Tan[a/2])]
The argument of Log is a number divided by its Conjugate, so its Norm is one, hence applying the preliminary result and multiplying by I (undoing part of the first factorization above) gives:
four = three /. Log[x_] ->I*I*Arg[x]
-Arg[(Sqrt[1 - e^2] - I*(-1 + e)*Tan[a/2])/(Sqrt[1 - e^2] + I*(-1 + e)*Tan[a/2])]
Divide by Sqrt[1 - e^2] to undo the factorization and we have:
four/Sqrt[1 - e^2]
Arg[(Sqrt[1 - e^2] - I*(-1 + e)*Tan[a/2])/(Sqrt[1 - e^2] + I*(-1 + e)*Tan[a/2])]/Sqrt[1 - e^2]
That expression involves I, it's true, but Arg is real-valued, so the value is certainly Real.
Bobby
On Fri, 17 Sep 2004 01:15:42 -0400 (EDT), Richard Chen <richard at doubleprime.com> wrote:
> The command:
>
> Integrate[1/(1 + e Cos[t]), {t, 0, a},
> Assumptions -> {-1 < e < 1, 0 < a < Pi}]
>
> leads to a complex valued result. I could not make
> mathematica to render the result in a form that is
> purely real. ComplexExpand, Refine all do not seem to work.
>
> Does anyone know how to make mathematica to simplify this
> result into a real form?
>
> Thanks for any info.
>
> Richard
>
>
>
--
DrBob at bigfoot.com
www.eclecticdreams.net
- References:
- How to simplify to a result that is real
- From: Richard Chen <richard@doubleprime.com>
- How to simplify to a result that is real