Re: SpinShow problem
- To: mathgroup at smc.vnet.net
- Subject: [mg56392] Re: [mg56339] SpinShow problem
- From: "David Park" <djmp at earthlink.net>
- Date: Sat, 23 Apr 2005 01:16:40 -0400 (EDT)
- Sender: owner-wri-mathgroup at wolfram.com
Shawn,
It appears that the commands in the Animation package do not make the actual
output graphics available to the user. That is not good! (Maybe someone will
show how one can access them.)
So as a fall back, you can make your own SpinShow. Here is an example.
plot1 = Plot3D[x Cos[y], {x, -3, 3}, {y, -3, 3},
Axes -> False,
Boxed -> False]
Convert this from SurfaceGraphics to Graphics3D so we can transform the xy
points.
plot2 = Graphics3D[plot1]
Next define one frame of the animation by rotating all xy points by angle t.
frame[t_] :=
Show[Graphics3D[
First[plot2] /. {x_?NumberQ, y_?NumberQ,
z_?NumberQ} -> {Cos[t]x - Sin[t]y, Sin[t]x + Cos[t]y, z}],
PlotRange -> {{-5, 5}, {-5, 5}, {-5, 5}},
Boxed -> False]
The following shows the animation and generates the plot frames using Table.
plotframes =
Table[frame[t], {t, 0, 2\[Pi] - \[Pi]/12, \[Pi]/12}]
SelectionMove[EvaluationNotebook[], All, GeneratedCell]
FrontEndTokenExecute["OpenCloseGroup"]; Pause[0.5];
FrontEndExecute[{FrontEnd`SelectionAnimate[200, AnimationDisplayTime -> 0.1,
AnimationDirection -> Forward]}]
Now pick a filename maybe using the following
filename = Experimental`FileBrowse[]
using name.gif for the actual file.
Then export with
Export[filename, plotframes, "GIF",
ConversionOptions -> {"Loop" -> True, "AnimationDisplayTime" -> 0.2}]
David Park
djmp at earthlink.net
http://home.earthlink.net/~djmp/
From: shawn peng [mailto:shawnpeng23 at yahoo.com.cn]
To: mathgroup at smc.vnet.net
I used SpinShow command to rotate a 3D graph. But when I export the results,
they can't be saved as .gif file. So, my question is how to save "SpinShow"
results as a .gif file in order to get a 3D movie?
Thanks.
Shawn