Re: Algebra of Einstein velocity addition
- To: mathgroup at smc.vnet.net
- Subject: [mg53825] Re: [mg53787] Algebra of Einstein velocity addition
- From: Bob Hanlon <hanlonr at cox.net>
- Date: Fri, 28 Jan 2005 02:44:32 -0500 (EST)
- Reply-to: hanlonr at cox.net
- Sender: owner-wri-mathgroup at wolfram.com
Addressing only your first question:
"Question 1: can you devise an explicit formula for einMul[x,k]? (I've found
one)"
Clear[einPlus, einMul];
einPlus[x_,y_]:=(x+y)/(1+x*y);
einMul[x_,1]=x;
einMul[x_,k_Integer?Positive]:=
einPlus[x,einMul[x,k-1]];
Needs["DiscreteMath`RSolve`"];
RSolve[
{a[x,n]==einPlus[x,a[x,n-1]],a[x,1]==x},
a[x,n], n]//FullSimplify
{{a[x, n] -> 2/((2/(x + 1) - 1)^n + 1) - 1}}
And@@Table[einMul[x,k]==2/((2/(x+1)-1)^k+1)-1,
{k,1,12}]//Simplify
True
Consequently,
Clear[einMul];
einMul[x_,k_Integer?Positive]:=
2/((2/(x+1)-1)^k+1)-1;
Bob Hanlon
>
> From: "Dr. Wolfgang Hintze" <weh at snafu.de>
To: mathgroup at smc.vnet.net
> Date: 2005/01/27 Thu AM 05:41:27 EST
> To: mathgroup at smc.vnet.net
> Subject: [mg53825] [mg53787] Algebra of Einstein velocity addition
>
> 100 years ago Albert Einstein discovered his law of adding two
> velocities x and y which is different from the ordinary sum, namely
>
> einPlus[x_, y_] := (x + y)/(1 + x*y)
>
> It is easy to show that velocities x, y, z, ... with a module less than
> unity form a commutative group under this law.
>
> I became interested in the algebraic properties of this law, and
> possible extensions. Here's the beginning of it.
>
> What about multiple additions of the same velocity, i.e.
>
> einPlus[x,x], einPlus[x,einPlus[x,x]], ...?
>
> Defining the k-fold Einstein Multiple recursively as
>
> einMul[x_, k_] := einPlus[x, einMul[x, k - 1]]
> einMul[x_, 1] = x;
>
> we find the first few terms using
>
> In[232]:=
> Table[{k, Simplify[einMul[x, k]]}, {k, 2, 10}]
>
> as
>
> Out[232]=
> {{2, (2*x)/(1 + x^2)}, {3, (x*(3 + x^2))/(1 + 3*x^2)}, {4, (4*(x +
> x^3))/(1 + 6*x^2 + x^4)},
> {5, (x*(5 + 10*x^2 + x^4))/(1 + 10*x^2 + 5*x^4)},
> {6, (6*x + 20*x^3 + 6*x^5)/(1 + 15*x^2 + 15*x^4 + x^6)},
> {7, (x*(7 + 35*x^2 + 21*x^4 + x^6))/(1 + 21*x^2 + 35*x^4 + 7*x^6)},
> {8, (8*(x + 7*x^3 + 7*x^5 + x^7))/(1 + 28*x^2 + 70*x^4 + 28*x^6 +
x^8)},
> {9, (x*(9 + 84*x^2 + 126*x^4 + 36*x^6 + x^8))/(1 + 36*x^2 + 126*x^4
+
> 84*x^6 + 9*x^8)},
> {10, (2*x*(5 + 60*x^2 + 126*x^4 + 60*x^6 + 5*x^8))/(1 + 45*x^2 +
> 210*x^4 + 210*x^6 + 45*x^8 +
> x^10)}}
>
> Question 1: can you devise an explicit formula for einMul[x,k]? (I've
> found one)
> Question 2: is it possible to extend the commutative group to a vector
> space using the Einstein Multiple k as the scalar factor?
> Question 3: can the algebraic properties be extended further?
> Question 4: is it possible to define an Einstein multiplication which is
> consistent with the multiple studied here?
>
> Regards,
> Wolfgang
>
>