Re: Solving Nonlinear Transcedental equations
- To: mathgroup at smc.vnet.net
- Subject: [mg66138] Re: Solving Nonlinear Transcedental equations
- From: Maxim <m.r at inbox.ru>
- Date: Sun, 30 Apr 2006 04:22:07 -0400 (EDT)
- References: <e2v73q$nju$1@smc.vnet.net>
- Sender: owner-wri-mathgroup at wolfram.com
On Sat, 29 Apr 2006 08:11:38 +0000 (UTC), shyam d <shyam.nitk at gmail.com>
wrote:
>
> I got a problem with Mathematica 5.1 ,as i am going to solve a Nonlinear
> Transcedental Equations, which are five variables with five eqations.it
> is
> not able to solve the problem and it is not showing any thing can any
> on please solve the problem using mathematica 5.1.
> and send me how to solve in mathematica 5.1
> The problem statement is
>
> solving the 5 simultaneous Non linear Transcedental equations
>
> cos(5a)+cos(5b)+cos(5c)+cos(5d)+cos(5e)=0
> cos(7a)+cos(7b)+cos(7c)+cos(7d)+cos(7e)=0
> cos(11a)+cos(11b)+cos(11c)+cos(11d)+cos(11e)=0
> cos(13a)+cos(13b)+cos(13c)+cos(13d)+cos(13e)=0
> cos(a)+cos(b)+cos(c)+cos(d)+cos(e)=4
>
> solve for a= ?,b= ?,c= ?,d= ?
>
> thanks
> shaym
>
>
It is possible to solve this using the symmetry of the problem. Convert
the equations to a polynomial system and choose new variables that involve
a,b,c,d,e in a symmetric way, such as x[1] = -a - b - c - d - e:
In[1]:= Lexpr = {Cos[5*a] + Cos[5*b] + Cos[5*c] + Cos[5*d] + Cos[5*e],
Cos[7*a] + Cos[7*b] + Cos[7*c] + Cos[7*d] + Cos[7*e],
Cos[11*a] + Cos[11*b] + Cos[11*c] + Cos[11*d] + Cos[11*e],
Cos[13*a] + Cos[13*b] + Cos[13*c] + Cos[13*d] + Cos[13*e],
Cos[a] + Cos[b] + Cos[c] + Cos[d] + Cos[e] - 4};
Lvar = {a, b, c, d, e};
n = Length@ Lvar;
Lexpr2 = Lexpr /. x : Alternatives @@ Lvar :> ArcCos[x] // TrigExpand;
Lvar2 = Array[x, n];
Laux = Lvar2 - Array[(-1)^#*Total[Times @@@ Subsets[Lvar, {#}]]&, n];
In[7]:= (Lsol = Solve[
GroebnerBasis[Join[Lexpr2, Laux], Lvar2, Lvar] == 0];) // Timing
Out[7]= {6.453*Second, Null}
The advantage is that the new system has only 9 solutions. The way we've
chosen the new variables, the cosines of a,b,c,d,e are the roots of the
monic polynomial with the coefficients x[i]:
In[8]:= (Mval = Array[
Root[#^n + Lvar2.#^Range[n - 1, 0, -1]&, #]&, n] /. Lsol;) // Timing
P = Mval[[1, 1, 1]];
Mval[[All, All, 2]]
Out[8]= {3.422*Second, Null}
Out[10]= {{7, 8, 9, 44, 45}, {6, 14, 15, 36, 37}, {1, 2, 3, 4, 5}, {13,
19, 22, 40, 42}, {12, 18, 23, 41, 43}, {17, 20, 27, 28, 34}, {16, 21, 26,
29, 35}, {11, 24, 30, 33, 38}, {10, 25, 31, 32, 39}}
This means that cosines of a,b,c,d,e are the roots of the polynomial P,
which has degree 45, and we can take, for example, the roots with the
indices 7, 8, 9, 44, 45 (in any order):
In[11]:= Lexpr /.
Thread[Lvar -> ArcCos[Root[P, #]& /@ {8, 9, 44, 45, 7}]] //
N[#, {Infinity, 20}]& // Chop
Out[11]= {0, 0, 0, 0, 0}
So in all we have 9*5! == 1080 solutions (for the cosines).
Maxim Rytin
m.r at inbox.ru