Mathematica 9 is now available
Services & Resources / Wolfram Forums
-----
 /
MathGroup Archive
2006
*January
*February
*March
*April
*May
*June
*July
*August
*September
*October
*November
*December
*Archive Index
*Ask about this page
*Print this page
*Give us feedback
*Sign up for the Wolfram Insider

MathGroup Archive 2006

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Limit

  • To: mathgroup at smc.vnet.net
  • Subject: [mg64712] Re: Limit
  • From: Maxim <m.r at inbox.ru>
  • Date: Tue, 28 Feb 2006 05:02:15 -0500 (EST)
  • References: <dtrvmt$lv0$1@smc.vnet.net>
  • Sender: owner-wri-mathgroup at wolfram.com

On Sun, 26 Feb 2006 10:25:33 +0000 (UTC), <sinankapcak at yahoo.com> wrote:

> i want to find the value of the limit
>
> 1+(2/(3+(4/(5+(6/(7+...
>
> how can i do that with Mathematica?
>
> Tnx..
>

The answer is 1/(Sqrt[E] - 1). The derivation is given here:  
http://arxiv.org/PS_cache/math/pdf/0508/0508227.pdf .

We can solve this problem in Mathematica by reformulating it in terms of  
recurrence equations. The nth convergent can be constructed like this:

In[1]:= x[n_] := Fold[
   With[{a = #2 + 1}, HoldForm[#2 + a/#]]&,
   2*n + 1, Range[2*n - 1, 1, -2]]

In[2]:= x[3]

Out[2]= HoldForm[1 + 2/HoldForm[3 + 4/HoldForm[5 + 6/7]]]

Therefore, we can view it as the nth term in the following sequence:

f[0] = 2*n + 1;
f[k_] := (2*n - 2*k + 2)/f[k - 1] + 2*n - 2*k + 1;

and we need to find the limit as n -> Infinity. RSolve can be applied to  
this equation directly, but the result will contain terms such as Gamma[n  
- k], making it indeterminate for k = n. So we make a suitable change of  
variables first:

In[3]:= RSolve[
   {y[k] == (2*n - 2*k + 2)/y[k - 1] + 2*n - 2*k + 1, y[0] == 2*n + 1} /.
     {y -> (y[n - #] - 1&), k -> n - k},
   y, k]

Out[3]= {{y -> Function[{k}, ((-1)^(-k + n)*2^(1 - k + n)*Sqrt[E]*(1  
+ k)*Gamma[2 + n])/(Sqrt[E]*Gamma[2 + k] + (-1)^n*2^(1 + n)*Gamma[2  
+ n]*Gamma[1 + k, -(1/2)] + (-1)^n*2^(1 + n)*k*Gamma[2 + n]*Gamma[1 + k,  
-(1/2)] - (-1)^n*2^(1 + n)*Gamma[2 + k]*Gamma[1 + n, -(1/2)] - (-1)^n*2^(1  
+ n)*n*Gamma[2 + k]*Gamma[1 + n, -(1/2)])]}}

In[4]:= Limit[y[0] - 1 /. %[[1]], n -> Infinity]

Out[4]= 1/(-1 + Sqrt[E])

In[5]:= % - ReleaseHold //@ x[11] // N

Out[5]= -1.2234657731369225*^-13

Maxim Rytin
m.r at inbox.ru


  • Prev by Date: Re: Re: Mathematica:recursion with 2 arguments?
  • Next by Date: Re: Limit of non-simple continued fraction
  • Previous by thread: Re: Limit
  • Next by thread: Re: Sequence@@List