MathGroup Archive 2006

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Limit of an expression?

  • To: mathgroup at smc.vnet.net
  • Subject: [mg67578] Re: Limit of an expression?
  • From: Jean-Marc Gulliet <jeanmarc.gulliet at gmail.com>
  • Date: Sat, 1 Jul 2006 05:12:09 -0400 (EDT)
  • Organization: The Open University, Milton Keynes, UK
  • References: <e7td7i$3lg$1@smc.vnet.net>
  • Sender: owner-wri-mathgroup at wolfram.com

Virgil Stokes wrote:
> In the following expression, s is an integer (>= 1), Lambda, Mu, and t 
> are real numbers and all > 0.
> What is the limit of the following as t goes to infinity?
> 
> \!\(\(1 - \[ExponentialE]\^\(\(-\[Mu]\)\ t\ \((s - 1 - \
> \[Lambda]\/\[Mu])\)\)\)\/\(s - 1 - \[Lambda]\/\[Mu]\)\)
> 
> --V. Stokes
> 
=====
Sorry for the mess with the fonts in my previous post. Please, find 
hereunder a readable version of it.
=====

Hi Virgil,

Contrary to some functions such as Integrate, Limit does not returned
conditional answers; that is, Limit will return a solution only if it
can establish the convergence or divergence of the expression without
taking in account the values of parameters. For instance, compare the
following answers to a simple limit

In[1]:=
Limit[E^(-t), t -> Infinity]

Out[1]=
0

In[2]:=
Limit[E^((-a)*t), t -> Infinity]

Out[2]=
         -a t
Limit[E    , t -> Infinity]

Of course, in the latter case you can add an assumption on the parameter
'a' and get the answer

In[3]:=
Limit[E^((-a)*t), t -> Infinity, Assumptions -> a > 0]

Out[3]=
0

Now, let's go back to your original question. In Mathematica form, we have

In[4]:=
Limit[(1 - E^((-mu)*t*(s - 1 - lambda/mu)))/
    (s - 1 - lambda/mu), t -> Infinity,
   Assumptions -> {Element[s, Integers], s > 0, lambda > 0,
     mu > 0, t > 0}]

Out[4]=
            -mu (-1 - lambda/mu + s) t
       1 - E
Limit[-------------------------------, t -> Infinity,
                    lambda
               -1 - ------ + s
                      mu

   Assumptions ->

    {Element[s, Integers], s > 0, lambda > 0, mu > 0, t > 0}]

As stated above, the expression is returned unevaluated since there is
indeed three possible answers depending on the respective value of s,
mu, and lambda. We can see by inspection that the limit of the
exponential function depends on the value of

In[5]:=
Simplify[E^((-mu)*t*(s - 1 - lambda/mu)),
   Assumptions -> {Element[s, Integers], s > 0, lambda > 0,
     mu > 0, t > 0}]

Out[5]=
  (lambda + mu - mu s) t
E

Therefore, we compute the different values in three steps

In[6]=
  Limit[(1 - E^((-mu)*t*(s - 1 - lambda/mu)))/
    (s - 1 - lambda/mu), t -> Infinity,
   Assumptions -> {Element[s,Integers], s > 0, lambda > 0,
     mu > 0, t > 0, lambda + mu - mu*s > 0}]

Out[6]=
Infinity

In[7]:=
Limit[(1 - E^((-mu)*t*(s - 1 - lambda/mu)))/
    (s - 1 - lambda/mu), t -> Infinity,
   Assumptions -> {Element[s, Integers], s > 0, lambda > 0,
     mu > 0, t > 0, lambda + mu - mu*s == 0}]

Out[7]=
0

In[8]:=
Limit[(1 - E^((-mu)*t*(s - 1 - lambda/mu)))/
    (s - 1 - lambda/mu), t -> Infinity,
   Assumptions -> {Element[s, Integers], s > 0, lambda > 0,
     mu > 0, t > 0, lambda + mu - mu*s < 0}]

Out[8]=
           mu
-(------------------)
   lambda + mu - mu s

Best regards,
Jean-Marc


  • Prev by Date: Re: Problem with LaplaceTransform and InverseLaplaceTransform
  • Next by Date: Re: Color names and the 10 elementary colors?
  • Previous by thread: Re: Limit of an expression?
  • Next by thread: Re: Re: Limit of an expression?