Re: Factor.....
- To: mathgroup at smc.vnet.net
- Subject: [mg71092] Re: Factor.....
- From: Paul Abbott <paul at physics.uwa.edu.au>
- Date: Wed, 8 Nov 2006 06:14:26 -0500 (EST)
- Organization: The University of Western Australia
- References: <eicnmq$g3i$1@smc.vnet.net>
In article <eicnmq$g3i$1 at smc.vnet.net>, gtsavdar at auth.gr wrote:
> How can i factor A^4 + 3 + y^2 (A,y reals) for example with
> Mathematica.....?
>
> In order to have:
> (A^2 + SQRT(y^2+3) + A·SQRT(2*SQRT(y^2+3))) · (A^2 + SQRT(y^2+3) -
> A·SQRT(2*SQRT(y^2+3)))
Seeking quadratic factors (using coercion into Series),
rs = Solve[(a^2 + a c + b)(a^2 + a e + d) == (a^4 + y^2 + 3) + O[a]^5,
{b, c, d, e}]
we simplify the result using the fact that y is real.
rs = Simplify[rs, Element[y, Reals]]
One obtains 6 solutions as three conjugate pairs. Here are the three
quadratic factorizations:
(a^2 + a c + b)(a^2 + a e + d) /. rs // Union
{
(a^2 - I Sqrt[2] a (3 + y^2)^(1/4) - Sqrt[3 + y^2])*
(a^2 + I Sqrt[2] a (3 + y^2)^(1/4) - Sqrt[3 + y^2]),
(a^2 - I Sqrt[3 + y^2]) (a^2 + I Sqrt[3 + y^2]),
(a^2 - Sqrt[2] a (3 + y^2)^(1/4) + Sqrt[3 + y^2])*
(a^2 + Sqrt[2] a (3 + y^2)^(1/4) + Sqrt[3 + y^2])
}
The last solution is the one you were looking for.
> OR:
> (y^2 - i·SQRT(A^4+3)) · (y^2 + i·SQRT(A^4+3))
You should have y not y^2 here. Seek quadratic factors of the form
Solve[(y + b) (y + c) == (a^4 + y^2 + 3) + O[y]^3, {b, c}]
Cheers,
Paul
_______________________________________________________________________
Paul Abbott Phone: 61 8 6488 2734
School of Physics, M013 Fax: +61 8 6488 1014
The University of Western Australia (CRICOS Provider No 00126G)
AUSTRALIA http://physics.uwa.edu.au/~paul