Mathematica 9 is now available
Services & Resources / Wolfram Forums
-----
 /
MathGroup Archive
2006
*January
*February
*March
*April
*May
*June
*July
*August
*September
*October
*November
*December
*Archive Index
*Ask about this page
*Print this page
*Give us feedback
*Sign up for the Wolfram Insider

MathGroup Archive 2006

[Date Index] [Thread Index] [Author Index]

Search the Archive

RE: Area of ellipse between major axis and ray through focus, given angle

  • To: mathgroup at smc.vnet.net
  • Subject: [mg71676] RE: [mg71601] Area of ellipse between major axis and ray through focus, given angle
  • From: "David Park" <djmp at earthlink.net>
  • Date: Sun, 26 Nov 2006 03:49:04 -0500 (EST)

The following is the parametrization of an ellipse in terms of the parameter
Theta.

ellipse[a_, b_][\[Theta]_] := {a*Cos[\[Theta]],
   b*Sin[\[Theta]]}

We must remember that the parameter Theta is not the same as the angle Phi
from the x axis. They are related by

\[Theta] == ArcTan[(a/b)*Tan[\[Phi]]];
\[Phi] == ArcTan[(b/a)*Tan[\[Theta]]];

The following makes a diagram if you have DrawGraphics. Otherwise skip the
diagram. Your diagram was fairly good.

Needs["DrawGraphics`DrawingMaster`"]

Module[{\[Phi]0 = Pi/4, a = 2, b = 1, segment,
    \[Phi]}, segment = FineGrainLines[0.05, 4][
      FineGrainPolygons[0.05, 4][
       FilledDraw[Norm[ellipse[2, 1][
          ArcTan[2*Tan[\[Phi]]]]],
        {\[Phi], 0, \[Phi]0}, Fills ->
         DodgerBlue]]];
    Draw2D[{ParametricDraw[ellipse[a, b][
        \[Theta]], {\[Theta], 0, 2*Pi}],
      segment /. DrawingTransform[
        #2*Cos[#1] & , #2*Sin[#1] & ],
      Line[{{0, 0}, ellipse[a, b][
         ArcTan[2*Tan[\[Phi]0]]]}],
      AngleArc[{0, 0}, {0, \[Phi]0}, 0.65,
       "\[Phi]", AAArrowOptions ->
        {HeadCenter -> 1/2, HeadLength ->
          0.2}, AATextOptions ->
        {Background -> DodgerBlue},
       AAStyleOptions -> {FontFamily ->
          "Courier", FontSize -> 12,
         FontWeight -> "Bold"}],
      Text["a", {a/2, 0}, {0, 1}],
      Text["b", {0, b/2}, {1, 0}]},
     AspectRatio -> Automatic,
     Frame -> False, Axes -> True,
     AxesStyle -> Gray, AxesOrigin -> {0, 0},
     Ticks -> None, PlotLabel ->
      "Ellipse Segment Area", TextStyle ->
      {FontFamily -> "Courier",
       FontSize -> 12, FontWeight -> "Bold"},
     Background -> Linen, ImageSize -> 450]];


We will first calculate the area of the segment in terms of a and b, the
major and minor semiaxes. The following calculates the radius of the ellipse
as a function of the angle from the x axis, Phi.

Norm[ellipse[a, b][ArcTan[(a/b)*Tan[\[Phi]]]]];
r[a, b][\[Phi]_] = Simplify[%, 0 < \[Phi] < Pi/2 &&
    0 < b < a]
(a*b*Sec[\[Phi]])/Sqrt[b^2 + a^2*Tan[\[Phi]]^2]

We can then use the standard integration formula for area in polar
coordinates to obtain the segment area.

areasolution[a_, b_][\[Phi]_] =
  Assuming[0 < \[Phi] < Pi/2 && 0 < b < a,
   Integrate[(1/2)*r[a, b][t]^2, {t, 0, \[Phi]}]]
(1/2)*a*b*ArcTan[(a*Tan[\[Phi]])/b]

We can check this out by taking 4 times the area of the first quadrant. We
have to use Limit to obtain an expression there. We obtain the standard
handbook solution for the area of an ellipse.

4 Limit[areasolution[a, b][\[Phi]], \[Phi] -> \[Pi]/2, Direction -> 1];
Simplify[%, 0 < b < a]
a*b*Pi

We can also calculate in terms of a and e, the eccentricity of the ellipse.
We substitute b in terms of e and a and simplify to obtain a radius
expression r2.

r[a, b][\[Phi]] /. b -> a*Sqrt[1 - e^2];
r2[a_, e_][\[Phi]_] = Simplify[%,
   a > 0 && 0 < e < 1]
(a*Sec[\[Phi]])/Sqrt[(-1 + e^2 - Tan[\[Phi]]^2)/
    (-1 + e^2)]

Evaluating the integral and simplifying takes a little more work.

step1 = Assuming[0 < \[Phi] < Pi/2 && a > 0 &&
     0 < e < 1, Integrate[
     (1/2)*r2[a, e][t]^2, {t, 0, \[Phi]}]];
step2 = ComplexExpand[Re[step1],
    TargetFunctions -> {Re, Im}];
areasolution2[a_, e_][\[Phi]_] =
  Simplify[step2, 0 < \[Phi] < Pi/2 && a > 0 &&
    0 < e < 1]
(1/2)*a^2*Sqrt[1 - e^2]*
  ArcTan[Tan[\[Phi]]/Sqrt[1 - e^2]]

Calculating the area of the entire ellipse, we again obtain the handbook
solution.

4*Limit[areasolution2[a, e][\[Phi]],
    \[Phi] -> Pi/2, Direction -> 1];
Simplify[%, 0 < \[Phi] < Pi/2 && a > 0 &&
   0 < e < 1]
a^2*Sqrt[1 - e^2]*Pi

David Park
djmp at earthlink.net
http://home.earthlink.net/~djmp/





From: Kelly Jones [mailto:kelly.terry.jones at gmail.com]

Given:

1) an ellipse with eccentricity "ec", one focus on the origin, and
the major axis along the x-axis

2) a ray through the origin at angle theta to the x-axis

Question:

What Mathematica function gives the relation/inverse relation between
the angle theta and the area of the ellipse between the x-axis and the ray?

I'm guessing one of EllipticE/EllipticF/EllipticK gives the area as a
function of theta, but I can't figure out which one.

I also can't figure out what function gives theta as a function of the area?

Finally, for a fixed value of ec (eccentricity), what are the power
series expansions for the functions taking theta to area and vica
versa?

Ugly drawing:

(* numbers chosen "randomly" for drawing purposes only *)
lower = ParametricPlot[{x,-(Sqrt[3]*Sqrt[3 - 8*x - 16*x^2])/8},
{x,-3/4,1/4}]
upper = ParametricPlot[{x, (Sqrt[3]*Sqrt[3 - 8*x - 16*x^2])/8},
{x,-3/4,1/4}]
line = Line[{{0,0},{.14,.27097}}]
arc = Circle[{0,0},.05,{0,1.09391}]

Show[lower,upper,Graphics[line],Graphics[arc],
     AspectRatio->Automatic,Ticks->None]



  • Prev by Date: Solving the cubic with Vieta's method
  • Next by Date: Re: Plotting a function -
  • Previous by thread: Re: Area of ellipse between major axis and ray through focus, given angle
  • Next by thread: Re: Area of ellipse between major axis and ray through focus, given angle