Re: FourierCosTransform
- To: mathgroup at smc.vnet.net
- Subject: [mg70450] Re: FourierCosTransform
- From: ab_def at prontomail.com
- Date: Mon, 16 Oct 2006 02:36:36 -0400 (EDT)
- References: <egi1ui$jbu$1@smc.vnet.net>
dimmechan at yahoo.com wrote:
> Consider the following function
>
> g[s_, y_] := 1/(E^(y*s)*s)
>
> Then (the integral exists in the Hadamard sense)
>
> FourierCosTransform[g[s, y], s, x]
> (-EulerGamma - Log[1/x^2 + 1/y^2] + Log[1/y^2])/Sqrt[2*Pi]
>
> FullSimplify[%, {x > 0, y > 0}]
> -((EulerGamma + Log[1 + y^2/x^2])/Sqrt[2*Pi])
>
> FullSimplify[FourierCosTransform[%, x, s], y > 0]
> (-1 + E^((-s)*y))/s
>
> As far as I know, the last result should be equal to g[s,y].
>
> Also based on a distributional approach (Sosa and Bahar 1992)
> the FourierCosTransform of g[s,y] should be
> -((EulerGamma + Log[x^2+ y^2])/Sqrt[2*Pi]).
>
> Can someone pointed me out was it is going here?
>
> Following the next procedure I succeed in getting a result
> similar with this of Sosa and Bahar (1992).
>
> Integrate[g[s, y]*Cos[s*x], {s, e, ee}, Assumptions -> 0 < e < ee];
> Normal[FullSimplify[Series[%, {e, 0, 2}], e > 0]];
> Normal[Block[{Message}, FullSimplify[Series[%, {ee, Infinity, 2}], ee >
> 0]]];
> DeleteCases[%, (a_)*Log[e], Infinity];
> DeleteCases[%, _[_, _[ee, _], _], Infinity];
> Limit[%, e -> 0];
> % /. -Log[a_] - Log[b_] :> -Log[a*b];
>
> FullSimplify[%]
> (1/2)*(-2*EulerGamma - Log[x^2 + y^2])
>
> I really appreciate any kind of help.
>
> Regards
> Dimitris
Here 1/t is actually the functional P(1/t) defined as
(P(1/t), phi(t)) ==
Integrate[(phi[t] - phi[0])/t, {t, 0, 1}] +
Integrate[phi[t]/t, {t, 1, Infinity}]
(which is why it is related to the regularization).
So, going by the definition, we have
In[1]:= Assuming[p > 0 && y > 0,
Sqrt[2/Pi]*(Integrate[(Cos[p*t]*E^(-y*t) - 1)/t, {t, 0, 1}] +
Integrate[Cos[p*t]*E^(-y*t)/t, {t, 1, Infinity}]) //
Simplify]
Out[1]= (-2*EulerGamma + I*Pi - Log[I*p - y] - Log[I*p + y])/Sqrt[2*Pi]
which is the correct value for the cosine transform (note the
coefficient 2 before EulerGamma).
Or we can integrate from eps to infinity and then take the regular
part:
In[2]:= Assuming[p > 0 && y > 0 && eps > 0,
Sqrt[2/Pi]*Integrate[Cos[p*t]*E^(-y*t)/t, {t, eps, Infinity}] //
Series[#, {eps, 0, 0}, Assumptions -> eps > 0]& //
SeriesCoefficient[#, 0] /. Log[eps] -> 0&]
Out[2]= (-2*EulerGamma - Log[-I*p - y] - Log[I*p - y])/Sqrt[2*Pi]
In some cases you can obtain the same result (the regular part of the
integral) from Integrate[..., GenerateConditions -> False].
Maxim Rytin
m.r at inbox.ru