Services & ResourcesWolfram ForumsMathGroup Archive

[Date Index] [Thread Index] [Author Index]

Re: Why is the negative root?

• To: mathgroup at smc.vnet.net
• Subject: [mg69656] Re: Why is the negative root?
• From: Paul Abbott <paul at physics.uwa.edu.au>
• Date: Wed, 20 Sep 2006 02:43:59 -0400 (EDT)
• Organization: The University of Western Australia
• References: <200609130803.EAA18412@smc.vnet.net><eeof1k$1n7$1@smc.vnet.net>

In article <eeof1k$1n7$1 at smc.vnet.net>, p-valko at tamu.edu wrote:

> I am a bit surprised by the "elitism" of the responses. 

Simply put, Root objects are preferable to explicit expressions 
involving radicals. Is that elitism?

The debate over "Roots versus radical expressions" depends on the 
application: what do you want to do with these roots once you have them? 
What is your end goal? 

In my experience, apart from quadratics, expressions involving radicals 
are just about useless. The trig expressions for real roots (below) are 
indeed more useful -- but, if I'm doing symbolic operations on the roots 
of some general polynomial, Root objects are much more useful. 

> Paul and Andrej and previously Daniel Lichtbau all defend the Root objects without
> telling the whole story. 

Really? What has been omitted? 

> In my opinion those objects are just pseudo-useful.

Why do you think that?

> If you plot Plot[Root[-1 + b #1 + #1^3 &, 1], {b,-10,10}]
> you will see that they are defending a monster.

There is nothing wrong with that plot. You have omitted the context 
explaining why you are interested in this Root over that range. Let's 
deconstruct why you might be interested in this Root. You obtain it as 
the root of

  z^3 + b z - 1 == 0

for b > -(3/2^(2/3)) and z > 0.

  Reduce[{z^3 + b z - 1 == 0, b > -(3/2^(2/3)), z > 0}, z]

Noting the condition on b, the relevant plot is

   Plot[Root[-1 + b # + #^3 &, 1], {b, -(3/2^(2/3)), 10}]

Alternatively, if you enter

  Reduce[{z^3 + b z - 1 == 0, z > 0, Element[b, Reals]}, z]

you will find the (piecewise) solution (involving two Root objects) for 
b real.

  f[b_] = Piecewise[{
    {Root[#^3 + b # - 1 & , 3], b <= -(3/2^(2/3))},    
    {Root[#^3 + b # - 1 & , 1], b > -(3/2^(2/3))}
  }]

  Plot[f[b], {b,-10,10}]

> But I am not going to start (continue) a debate on faith. Rather I am
> trying to formulate my question on a language even hard-core Mathematica 
> defenders can accept:
> 
> "Assuming that the coefficients are real and I am interested only in
> real roots, how do I persuade Reduce to give the formulas 69 - 72 of
> 
>  http://mathworld.wolfram.com/CubicFormula.html ?

See the American Journal of Physics 52(3), 269 (1984) and the Tricks of 
the Trade column in The Mathematica Journal 2(3), where the real roots 
of cubics are discussed. In particular, a cubic of the form

  x^3 - 3 a x + 2 b == 0 

has three real roots iff 0 < b^2 < a^3. So, using

  r = ToRadicals[Reduce[{x^3 - 3 a x + 2 b == 0}, x]]

and

  Simplify[ComplexExpand[#], 0 < b^2 < a^3] & /@ r

effectively gives you the formulas you are after.

Cheers,
Paul

_______________________________________________________________________
Paul Abbott                                      Phone:  61 8 6488 2734
School of Physics, M013                            Fax: +61 8 6488 1014
The University of Western Australia         (CRICOS Provider No 00126G)    
AUSTRALIA                               http://physics.uwa.edu.au/~paul

• References:
  • Why is the negative root?
    • From: p-valko@tamu.edu