Re: Beta function, Integral
- To: mathgroup at smc.vnet.net
- Subject: [mg79885] Re: [mg79858] Beta function, Integral
- From: Bob Hanlon <hanlonr at cox.net>
- Date: Wed, 8 Aug 2007 04:45:51 -0400 (EDT)
- Reply-to: hanlonr at cox.net
It is correct.
int1 = Integrate[t^(p - 1)*(1 - t)^(q - 1), {t, 0, 1},
Assumptions -> {p > 0, q > 0}]
(Pi*Csc[Pi*q]*Gamma[p])/
(Gamma[1 - q]*Gamma[p + q])
To force an alternate form add the assumption that p and q are integers.
int2 = Integrate[t^(p - 1)*(1 - t)^(q - 1), {t, 0, 1},
Assumptions -> {Element[{p, q}, Integers],
p > 0, q > 0}]
(Gamma[p]*Gamma[q])/Gamma[p + q]
Verifying that the forma are equivalent and equal to Beta function
int1 == int2 == Beta[p, q] // FullSimplify
True
Hence
Solve[int1 == int2, Gamma[1 - q]][[1, 1]]
Gamma[1 - q] -> (Pi*Csc[Pi*q])/
Gamma[q]
FullSimplify[Equal @@ %]
True
Bob Hanlon
---- Asim <maa48 at columbia.edu> wrote:
>
> Hi
>
> The following integral does not seem to give the correct answer. The
> answer should be the Euler Beta function, Beta[p,q]. Can anybody let
> me know what I am doing wrong? Or is this a bug?
>
>
> In[12]:= Integrate[t^{p - 1}*(1 - t)^(q - 1), {t, 0, 1}, Assumptions -
> > {p > 0, q > 0}]
>
> Out[12]= {(\[Pi] Csc[\[Pi] q] Gamma[p])/(Gamma[1 - q] Gamma[p + q])}
>
>
> Thanks
>
> Asim Ansari
>
>