Re: Limits of Nested Expressions
- To: mathgroup at smc.vnet.net
- Subject: [mg80762] Re: [mg80718] Limits of Nested Expressions
- From: Bob Hanlon <hanlonr at cox.net>
- Date: Sat, 1 Sep 2007 00:24:02 -0400 (EDT)
- Reply-to: hanlonr at cox.net
Generalizing to Sqrt[c + Sqrt[c + Sqrt[c + ...]]]
f[c_] = x /. Solve[Sqrt[c + x] == x, x][[2]]
(1/2)*(Sqrt[4*c + 1] + 1)
Looking at values of c that produce an integer
Reduce[f[c] == n, c, Integers]
Element[n | c, Integers] &&
n >= 1 && c == n^2 - n
Simplify[f[n (n - 1)], n >= 1]
n
Table[FixedPoint[Sqrt[n (n - 1) + #] &, RandomReal[]], {n, 10}]
{1.,2.,3.,4.,5.,6.,7.,8.,9.,10.}
Bob Hanlon
---- Bob Hanlon <hanlonr at cox.net> wrote:
> FixedPoint[N[Sqrt[5 + #], 50] &, 5]
>
> 2.7912878474779200032940235968640042444922282883840
>
> x /. Solve[Sqrt[5 + x] == x, x][[1]]
>
> (1/2)*(1 + Sqrt[21])
>
> N[%, 50]
>
> 2.7912878474779200032940235968640042444922282883840
>
> % == %%%
>
> True
>
>
> Bob Hanlon
>
> ---- Yaroslav Bulatov <yaroslavvb at gmail.com> wrote:
> > Is it possible to compute the following limit in Mathematica 6?
> > Limit[Nest[Sqrt[5 + #]&, 5, n], n -> Infinity]
> >
> > It used to be possible through Calculus`Limit package, which seems to
> > be gone
> >
> >