MathGroup Archive 2007

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Solve, when I already know 1 solution

  • To: mathgroup at smc.vnet.net
  • Subject: [mg73101] Re: [mg73080] Solve, when I already know 1 solution
  • From: Andrzej Kozlowski <akoz at mimuw.edu.pl>
  • Date: Fri, 2 Feb 2007 05:31:35 -0500 (EST)
  • References: <200702010851.DAA11372@smc.vnet.net> <970E9654-6835-47DA-BF4F-D49C0413AB81@mimuw.edu.pl>

On 1 Feb 2007, at 14:18, Andrzej Kozlowski wrote:

>
> On 1 Feb 2007, at 09:51, DOD wrote:
>
>> I am trying to solve the following system of equations for, X, Y, and
>> Z:
>>
>>
>>
>> {X((16  X ^3 - 39  X ^2  Y + 5  X  Y ^2 + 8  Y ^3 +  ((19  X ^2 -  
>> 10 X  Y +
>> 3  Y ^2) )  Z + 3   ((X + Y) )  Z ^2 + Z ^3) ) == 9  c, X Y ((29   
>> X ^2 - 2
>> Y   ((4  Y + Z) ) - 2  X   ((9  Y + 5  Z) )) ) ==  (-9 )  c, Z  
>> ((10  X ^3 +
>> 81  Y (Y - Z) ( (-1 ) + Z) +  X  Y   ((81 - &9  Y + 2  Z) ) + X  
>> ^2   (( (-
>> 81 ) + 72  Y + 4  Z))) ) == 9  c}
>>
>> (sorry for the bad formatting, I don't know a convenient way to  
>> copy this
>> info from mathematica.  Anyway, the precise polynomial isn't  
>> important. )
>>
>> I would like a symbolic solution in c.  So Solve chews on this  
>> forever
>> without giving a solution.  Now, it so happens that I already know a
>> solution is X=Y=Z =c^(1/4), and I strongly suspect that all the other
>> solutions, real or imaginary, are of the form X=q c^(1/4),Y=r c^ 
>> (1/4),Z= s
>> c^(1/4), for some (q,r,s).  Is there any way I can use this info  
>> to help
>> Solve along, and give me all the solutions?
>>
>>
>> -- DOD
>
>
> I doubt that in the case of a multivariate system knowing one  
> solution will be of any help in finding the general solution.  
> Moreover, I can't understand your conjecture that
>
>> all the other
>> solutions, real or imaginary, are of the form X=q c^(1/4),Y=r c^ 
>> (1/4),Z= s
>> c^(1/4), for some (q,r,s)
>
> Given a non-zero c, any three number X,Y,Z can be written in the  
> above form for some (q,r,s). There are actually 4 obvious solutions  
> of this form, where q=r=s is an element of the set {I,-I,1,-1} but  
> these are certainly not all solutions (since for numerical values  
> of d it is easy to find solutions not equal to any of these).
>
> Andrzej Kozlowski

Since all attempts to find the general solution to these equations do  
seem to take impossibly long, it may be interesting to se how one can  
find some solutions other than the obvious ones. We start with the  
equations:

In[1]:=
p = {X*(16*X^3 - 39*X^2*Y +
        5*X*Y^2 + 8*Y^3 +
        (19*X^2 - 10*X*Y +
          3*Y^2)*Z + 3*(X + Y)*
         Z^2 + Z^3) == 9*c,
     X*Y*(29*X^2 - 2*Y*(4*Y +
          Z) - 2*X*(9*Y +
          5*Z)) == -9*c,
     Z*(10*X^3 + 81*Y*(Y - Z)*
         (-1 + Z) +
        X*Y*(81 - 79*Y + 2*Z) +
        X^2*(-81 + 72*Y +
          4*Z)) == 9*c};

I prefer to replace c by d^4 in order to have fewer radicals:


p = p /. c -> d^4;

Let's simply try to find only solutions for which Z==Y (note that the  
4 solutions found earlier all have this property):

p1 = p /. Equal -> Subtract;
p2 = p1 /. Z -> Y;
gr = GroebnerBasis[p2, {X, Y}];


Reduce[gr == 0, {X, Y}]


(d == 0 && X == 0) ||
   (X == -d && Y == -d) ||
   (X == d && Y == d) ||
   ((X == (-I)*d || X == I*d) &&
    Y == X) ||
   ((d == -(1549657902645/
          387755552 +
         (151225265385*Sqrt[
           105])/387755552)^
        (1/4) || d ==
      (-I)*(1549657902645/
          387755552 +
         (151225265385*Sqrt[
           105])/387755552)^
        (1/4) || d ==
      I*(1549657902645/
          387755552 +
         (151225265385*Sqrt[
           105])/387755552)^
        (1/4) || d ==
      (1549657902645/387755552 +
        (151225265385*Sqrt[105])/
         387755552)^(1/4) ||
     d == -6*Sqrt[3]*
       (11290/(425146201 +
          41488413*Sqrt[105]))^
        (1/4) || d ==
      -6*I*Sqrt[3]*
       (11290/(425146201 +
          41488413*Sqrt[105]))^
        (1/4) || d ==
      6*I*Sqrt[3]*
       (11290/(425146201 +
          41488413*Sqrt[105]))^
        (1/4) || d == 6*Sqrt[3]*
       (11290/(425146201 +
          41488413*Sqrt[105]))^
        (1/4)) &&
    X == (7800332805 -
       47647928*d^4)/
      50408421795 &&
    Y == (8*(2669927*d^4 +
        5429409750))/50408421795)

We can see that for special values of d there are solutions other  
than the generic ones. Note that using Solve instead of Reduce will  
return only the generic solutions:


Solve[gr == 0, {X, Y}]


{{X -> -d, Y -> -d},
   {X -> (-I)*d, Y -> (-I)*d},
   {X -> I*d, Y -> I*d},
   {X -> d, Y -> d}}

Andrzej Kozlowski


  • Prev by Date: Re: rather complicated NonlinearFit
  • Next by Date: Re: Limit question
  • Previous by thread: Solve, when I already know 1 solution
  • Next by thread: Re: Solve, when I already know 1 solution