Re: NIntegrate - problems with HoldAll property(?)
- To: mathgroup at smc.vnet.net
- Subject: [mg73123] Re: [mg73113] NIntegrate - problems with HoldAll property(?)
- From: Carl Woll <carlw at wolfram.com>
- Date: Sun, 4 Feb 2007 06:37:11 -0500 (EST)
- References: <200702031000.FAA06648@smc.vnet.net>
gotcha wrote:
>While playing with my new Workbench toy, I think I have found the cause of a problem I am running into with NIntegrate. If so, any way around this one?
>
>
>
>>f1[x_] := First[Position[{1, 3, 5, 7, 9, Infinity}, y_ /; y>= x, Infinity, 1]][[1]]
>>NIntegrate[f1[i], {i, 0,7}]
>>
>>
>
>This fails with the message:
>First::first: {} has a length of zero and no first element
>NIntegrate::inum: Integrand {} is not numerical at {i} = {3.5`}
>
>i.e. I am chucked out on the first Nintegrate call (when i=3.5)
>
>When I track this through the debugger, I notice that "i" is not resolved to "3.5" when it is passed to the f1 function, and so the function cannot execute. i.e. the variable is still set to "i", rather than "3.5" when it hits the function. This is ok for a wide range of functions, but not this one.
>
>I think this is the key to the problems I am having with a more complex problem. If so, can anyone see a way around it? i.e. can I use NIntegrate, and get it to call the functions with numerical values?
>
>Digging deeper, I can see that NIntegrate has the "HoldAll" property (I'm sure there is a good reason for this), but I still can't get round this - I tried putting in Evaluate[] in a couple of places.
>
>Any help out there?
>
>rgds
>David
>
>
To prevent f1[x] from ever being called when x is not numerical, use the
definition:
f1[x_?NumericQ] := First[Position[{1, 3, 5, 7, 9, Infinity}, y_ /; y>= x, Infinity, 1]][[1]]
instead. Then, your integral will still produce error messages, but will return a valid result:
In[11]:=
f1[x_?NumericQ] := First[Position[{1, 3, 5, 7, 9, Infinity}, y_ /; y â?¥ x, Infinity, 1]][[1]]
NIntegrate[f1[i], {i, 0, 7}]
(* error messages suppressed *)
Out[12]=
19.0012
Another possibility for this particular example is to use Interpolation and Integrate instead. For example:
In[13]:=
f2 = Interpolation[{{-100, 0}, {1, 1}, {3, 2}, {5, 3}, {7, 4}, {9, 5}, {100, 6}}, InterpolationOrder -> 0];
Integrate[f2[x], {x, 0, 7}]
Out[14]=
19
Carl Woll
Wolfram Research
- Follow-Ups:
- FindFit and NonlinearRegress: Advantages/Disadvantages?
- From: gardyloo <gardyloo@mail.wsu.edu>
- FindFit and NonlinearRegress: Advantages/Disadvantages?
- References:
- NIntegrate - problems with HoldAll property(?)
- From: gotcha <david.shorthouse@credit-suisse.com>
- NIntegrate - problems with HoldAll property(?)