Re: limit
- To: mathgroup at smc.vnet.net
- Subject: [mg78652] Re: limit
- From: sashap <pavlyk at gmail.com>
- Date: Fri, 6 Jul 2007 03:23:16 -0400 (EDT)
- References: <f6d9si$2l5$1@smc.vnet.net>
Hi,
I actually found a way to symbolically prove the result.
One has to use different recurrence equation with respect
to lower integer parameter:
In[189]:= Clear[q, r, RecEq];
In[190]:=
r[e_] = -2^(-1 - 4 e) Gamma[
1 - 2 e] Gamma[1/2 - e]^2 HypergeometricPFQ[{1/2 - e, 1/2 - e,
1/2 - e, 1 - e}, {1/2, 1, 1}, 1] Sin[e Pi]/Pi;
In[191]:=
RecEq = 15/
2 e HypergeometricPFQ[{1/2 - e, 1/2 - e, 1/2 - e, 1 - e}, {1/2, 1,
1}, 1] -
45/16 (3 + 14 e + 8 e^2) HypergeometricPFQ[{1/2 - e, 1/2 - e,
1/2 - e, 1 - e}, {1, 1, 3/2}, 1] +
5/16 (65 + 188 e + 132 e^2 + 32 e^3) HypergeometricPFQ[{1/2 - e,
1/2 - e, 1/2 - e, 1 - e}, {1, 1, 5/2}, 1] -
1/2 (2 + e)^3 (3 + 2 e) HypergeometricPFQ[{1/2 - e, 1/2 - e,
1/2 - e, 1 - e}, {1, 1, 7/2}, 1];
In[192]:=
RecEq = 24 e HypergeometricPFQ[{1/2 - e, 1/2 - e, 1/2 - e, 1 - e}, {1/
2, 1, 1}, 1] +
1/4 (-90 - 396 e - 144 e^2) HypergeometricPFQ[{1/2 - e, 1/2 - e,
1/2 - e, 1 - e}, {1/2, 1, 2}, 1] +
1/8 (429 + 1032 e + 540 e^2 + 96 e^3) HypergeometricPFQ[{1/2 - e,
1/2 - e, 1/2 - e, 1 - e}, {1/2, 1, 3}, 1] -
1/8 (2 + e) (5 + 2 e)^3 HypergeometricPFQ[{1/2 - e, 1/2 - e,
1/2 - e, 1 - e}, {1/2, 1, 4}, 1];
In[193]:= RecEq /. e -> 1`15*^-5
Out[193]= 0.*10^-15
In[194]:=
q[e_] = r[e] /.
First[Solve[RecEq == 0,
HypergeometricPFQ[{1/2 - e, 1/2 - e, 1/2 - e, 1 - e}, {1/2, 1, 1},
1]]]
Out[194]= -(1/(3 e \[Pi]))
2^(-4 - 4 e)
Gamma[1 - 2 e] Gamma[
1/2 - e]^2 (-(1/
4) (-90 - 396 e - 144 e^2) HypergeometricPFQ[{1/2 - e, 1/2 - e,
1/2 - e, 1 - e}, {1/2, 1, 2}, 1] -
1/8 (429 + 1032 e + 540 e^2 + 96 e^3) HypergeometricPFQ[{1/2 - e,
1/2 - e, 1/2 - e, 1 - e}, {1/2, 1, 3}, 1] +
1/8 (2 + e) (5 + 2 e)^3 HypergeometricPFQ[{1/2 - e, 1/2 - e,
1/2 - e, 1 - e}, {1/2, 1, 4}, 1]) Sin[e \[Pi]]
In[195]:=
Collect[q[e], _HypergeometricPFQ,
Limit[#, e -> 0, Direction -> -1] &] /. e -> 0
Out[195]= -(1/8)
Oleksandr Pavlyk
Special Functions Developer
Wolfram Research Inc.
On Jul 5, 3:34 am, DrMajorBob <drmajor... at bigfoot.com> wrote:
> That seems plausible, of course, but numerical results contradict it, both
> for the original expression and the denominator derivative.
>
> Start by taking apart the OP's expression:
>
> Clear[expr, noProblem, zero, infinite]
> expr[s_] = -((2^(-2 + s)*Cos[(1/4)*Pi*(1 + s)]*Gamma[(1 + s)/4]^2*
> Gamma[(1 +
> s)/2]*
> HypergeometricPFQ[{1/4 + s/4, 1/4 + s/4, 1/4 + s/4,
> 3/4 + s/4},
> {1/2, 1, 1}, 1])/Pi);
> List @@ % /. s -> 1
>
> {-1, 1/2, 1/\[Pi], 0, \[Pi], 1, \[Infinity]}
>
> noProblem[s_] = expr[s][[{1, 2, 3, 5, 6}]]
> zero[s_] = expr[s][[4]]
> infinite[s_] = expr[s][[-1]]
>
> -(2^(-2 + s) Gamma[(1 + s)/4]^2 Gamma[(1 + s)/2])/\[Pi]
>
> Cos[1/4 \[Pi] (1 + s)]
>
> HypergeometricPFQ[{1/4 + s/4, 1/4 + s/4, 1/4 + s/4, 3/4 + s/4}, {1/2,
> 1, 1}, 1]
>
> Here's essentially the same result you have:
>
> D[zero[s], s] /. s -> 1
> D[1/infinite[s], s] /. s -> 1
>
> -\[Pi]/4
> 0
>
> But the latter derivative is clearly wrong (probably due to some
> simplification rule, applied without our knowledge, that isn't correct at
> s=1):
>
> Clear[dy, infInverse]
> dy[f_, dx_, digits_] := N[(f[1 - dx] - f[1 - 2 dx])/dx, digits]
> infInverse[s_] = 1/infinite[s];
>
> Table[dy[infInverse, 10^-k, 25], {k, 1, 10}]
>
> {-1.923427116516395532881478, -2.983463609047004067632190, \
> -3.125313973445201143419500, -3.139959997528752908922902, \
> -3.141429339969442289280062, -3.141576321747481534963308, \
> -3.141591020400759167851555, -3.141592490270841802264744, \
> -3.141592637257897614551351, -3.141592651956603671268599}
>
> Table[Pi + dy[infInverse, 10^-k, 30], {k, 10, 20}]
>
> {1.63318956719404435692*10^-9, 1.6331895676743358738*10^-10,
> 1.633189567722365025*10^-11, 1.63318956772716794*10^-12,
> 1.6331895677276482*10^-13, 1.633189567727696*10^-14,
> 1.63318956772770*10^-15, 1.6331895677277*10^-16,
> 1.633189567728*10^-17, 1.63318956773*10^-18, 1.6331895677*10^-19}
>
> So the denominator limit is (almost certainly) -Pi, and the original limit
> is
>
> noProblem[1] D[zero[s], s]/-Pi /. s -> 1
> % // N
>
> -1/8
> -0.125
>
> which agrees perfectly with the OP's calculations and with these:
>
> Table[N[1/8 + expr[1 - 10^-k], 20], {k, 1, 10}]
>
> {-0.031802368727291105600, -0.0029147499047748859136, \
> -0.00028902994360074334672, -0.000028878738171604118632, \
> -2.8876314481087565099*10^-6, -2.8876072131304841863*10^-7, \
> -2.8876047896519244498*10^-8, -2.8876045473042611497*10^-9, \
> -2.8876045230694967464*10^-10, -2.8876045206460203254*10^-11}
>
> I don't know how to prove the result symbolically, however.
>
> Bobby
>
> On Wed, 04 Jul 2007 04:28:36 -0500, dh <d... at metrohm.ch> wrote
>
>
>
>
>
> > Hi Dimitris,
>
> > I think the limit is -Infinity.
>
> > consider the following trick :
>
> > f1=2^(-2+s)*Cos[(1/4)*Pi*(1+s)]*Gamma[(1+s)/4]^2*Gamma[(1+s)/2]
>
> > f2= 1/HypergeometricPFQ[{1/4 + s/4, 1/4 + s/4, 1/4 + s/4, 3/4 + s/4},
>
> > {1/2, 1, 1}, 1]
>
> > then we are interessted in the limit of f1/f2. As both these expressions
>
> > are 0 for s=1, we can take the quotient of the drivatives:
>
> > D[f1,s]=-\[Pi]^2/8
>
> > D[f2,s]= 0
>
> > therefore we get -Infinity
>
> > hope this helps, Daniel
>
> > dimitris wrote:
>
> >> Hello.
>
> >> Say
>
> >> In[88]:=
>
> >> o = -((2^(-2 + s)*Cos[(1/4)*Pi*(1 + s)]*Gamma[(1 + s)/4]^2*Gamma[(1 +
>
> >> s)/2]*
>
> >> HypergeometricPFQ[{1/4 + s/4, 1/4 + s/4, 1/4 + s/4, 3/4 + s/4},
>
> >> {1/2, 1, 1}, 1])/Pi);
>
> >> I am interested in the value at (or as s->) 1.
>
> >> I think there must exist this value (or limit) at s=1.
>
> >> In[89]:=
>
> >> (N[#1, 20] & )[(o /. s -> 1 - #1 & ) /@ Table[10^(-n), {n, 3, 10}]]
>
> >> Out[89]=
>
> >> {-0.12528902994360074335,-0.12502887873817160412,-0.12500288763144810876,-0.\
>
> >> 12500028876072131305,-0.12500002887604789652,-0.12500000288760454730, -0.\
>
> >> 12500000028876045231,-0.12500000002887604521}
>
> >> However both
>
> >> o/.s->1
>
> >> and
>
> >> Limit[o,s->1,Direction->1 (*or -1*)]
>
> >> does not produce anything.
>
> >> Note also that
>
> >> In[93]:=
>
> >> 2^(-2 + s)*Cos[(1/4)*Pi*(1 + s)]*Gamma[(1 + s)/4]^2*Gamma[(1 + s)/
>
> >> 2] /. s -> 1
>
> >> HypergeometricPFQ[{1/4 + s/4, 1/4 + s/4, 1/4 + s/4, 3/4 + s/4}, {1/2,
>
> >> 1, 1}, 1] /. s -> 1
>
> >> Out[93]=
>
> >> 0
>
> >> Out[94]=
>
> >> Infinity
>
> >> So am I right and the limit exist (if yes please show me a way to
>
> >> evaluate it) or not
>
> >> (in this case explain me why; in either case be kind if I miss
>
> >> something fundamental!)
>
> >> Thanks
>
> >> Dimitris
>
> --
>
> DrMajor... at bigfoot.com