a definite integral and a workaround
- To: mathgroup at smc.vnet.net
- Subject: [mg78380] a definite integral and a workaround
- From: dimitris <dimmechan at yahoo.com>
- Date: Fri, 29 Jun 2007 05:53:21 -0400 (EDT)
I have posted some time ago a similar message
but in view of the recent thread called "two integrals"
here we go...
In[1]:=
$Version
Out[1]=
"5.2 for Microsoft Windows (June 20, 2005)"
I am interested in the integral
In[2]:=
Integrate[u*Sin[u*x]*Exp[(-y)*(Sqrt[1 + m^2*u^2]/m)], {u, 0,
Infinity}, GenerateConditions -> False]
Out[2]=
Integrate[(u*Sin[u*x])/E^((Sqrt[1 + m^2*u^2]*y)/m), {u, 0, Infinity},
GenerateConditions -> False]
I.e. it stays unevaluated within Mathematica (the same holds true for
another CAS I tried).
Say,
In[6]:=
integrand = u*Sin[u*x]*Exp[(-y)*(Sqrt[1 + m^2*u^2]/m)]
Out[6]=
(u*Sin[u*x])/E^((Sqrt[1 + m^2*u^2]*y)/m)
Then,
In[26]:=
ff=Integrate[integrand, x, y]
Normal[Series[%, {y, 0, 5}]]
(Integrate[#1, {u, 0, Infinity}, GenerateConditions -> False] & ) /@ %
Out[26]=
(m*Cos[u*x])/(E^((Sqrt[1 + m^2*u^2]*y)/m)*Sqrt[1 + m^2*u^2])
Out[27]=
(m*Cos[u*x])/Sqrt[1 + m^2*u^2] - y*Cos[u*x] + (Sqrt[1 +
m^2*u^2]*y^2*Cos[u*x])/(2*m) - ((1 + m^2*u^2)*y^3*Cos[u*x])/(6*m^2) +
((1 + m^2*u^2)^(3/2)*y^4*Cos[u*x])/(24*m^3) - ((1 +
m^2*u^2)^2*y^5*Cos[u*x])/(120*m^4)
Out[28]=
(m*BesselK[0, Sqrt[x^2]/Sqrt[m^2]])/Sqrt[m^2] - (y^2*BesselK[1,
Sqrt[x^2]/Sqrt[m^2]])/(2*m*Sqrt[x^2]) +
(Sqrt[m^2]*y^4*BesselK[2, Sqrt[x^2]/Sqrt[m^2]])/(8*m^3*x^2)
Pay notice to the last output. Next
In[31]:=
FullSimplify /@ Normal[Series[BesselK[0, Sqrt[x^2 + y^2]/m], {y, 0,
5}]]
Out[31]=
BesselK[0, Sqrt[x^2]/m] - (y^2*BesselK[1, Sqrt[x^2]/m])/
(2*m*Sqrt[x^2]) + (y^4*BesselK[2, Sqrt[x^2]/m])/(8*m^2*x^2)
Comparing the outputs 28 and 31 we conclude that
Integrate[ff,{u,0,Infinity}]=BesselK[0, Sqrt[x^2 + y^2]/m]
so the desiring integral is given by
In[33]:=
FunctionExpand[D[BesselK[0, Sqrt[x^2 + y^2]/m], x, y]]
Out[33]=
(x*y*BesselK[2, Sqrt[x^2 + y^2]/m])/(m^2*(x^2 + y^2))
Let's check it!
In[44]:=
NIntegrate[u*Sin[u*x]*Exp[(-y)*(Sqrt[1 + m^2*u^2]/m)] /. {x -> 1/2, m -
> 2, y -> 2}, {u, 0, Infinity}]
Out[44]=
0.08892633231521632
In[48]:=
(x*y*BesselK[2, Sqrt[x^2 + y^2]/m])/(m^2*(x^2 + y^2)) /. {x -> 1/2, m -
> 2, y -> 2}
N[%]
Out[48]=
(1/17)*BesselK[2, Sqrt[17]/4]
Out[49]=
0.08892633231440279
Dimitris