Re: simplifications
- To: mathgroup at smc.vnet.net
- Subject: [mg74540] Re: simplifications
- From: Peter Pein <petsie at dordos.net>
- Date: Sun, 25 Mar 2007 01:25:11 -0500 (EST)
- References: <eu1rpt$lf6$1@smc.vnet.net>
dimitris schrieb:
> Hello.
>
> Below I use Mathematica to get some definite integrals along with
> simplifications
> of the results.
>
> ln[9]:=
> f1 = FullSimplify[Integrate[x*(Sin[x]/(1 + Cos[x]^2)), {x, 0, Pi}]]
> Out[9]=
> (1/8)*Pi*(2*Pi + 8*I*ArcSinh[1] + Log[((2 - Sqrt[2])^(9*I)*(2 +
> Sqrt[2])^(7*I))/(10 - 7*Sqrt[2])^(3*I)] +
> Log[(6 + 4*Sqrt[2])^(-6*I)] - I*Log[10 + 7*Sqrt[2]])
...
>
> In[14]:=
> f6 = FullSimplify[Integrate[x*(Sin[x]/(1 + Cos[x]^2)), {x, -Pi, Pi}]]
> Out[14]=
> (1/4)*Pi*(2*Pi + 8*I*ArcSinh[1] + Log[((2 - Sqrt[2])^(9*I)*(2 +
> Sqrt[2])^(7*I))/(10 - 7*Sqrt[2])^(3*I)] +
> Log[(6 + 4*Sqrt[2])^(-6*I)] - I*Log[10 + 7*Sqrt[2]])
>
> No matter what I try I couldn't simplify f1 and f6 directly to Pi^2/4
> and Pi^2/2.
>
...
>
> Can somebody guess why we f1 and f6 do not simplify directly as the
> other fi?
>
>
Hi Dimitris,
maybe the minimuf of the denominator causes this trouble.
My first attempt was
In[1]:=
Apply[
Timing[
ClearCache[];
MemoryConstrained[
FullSimplify[Integrate[x*(Sin[x]/(1 + Cos[x]^2)), {x, ##1}]],
512*1024^2 (* give Mathematica 512MB to waste *)]] & ,
{{0, Pi/2, Pi}, {-Pi, -Pi/2, Pi/2, Pi}}, {1}]
Out[1]=
{{ 46.531*Second, Pi^2/4},
{301.516*Second, $Aborted}}
so this is not an option.
The use of ComplexExpand gives (better) results:
In[2]:=
Timing[
ClearCache[];
FullSimplify[ComplexExpand[
Integrate[x*(Sin[x]/(1 + Cos[x]^2)), {x, #1, Pi}]]]]& /@ {0, -Pi}
Out[2]=
{{43.797*Second, Pi^2/4},
{39.562*Second, Pi^2/2}}
But the best way to do this seems to be a substitution:
In[3]:=
Timing[
ClearCache[];
Integrate[
TrigExpand[x*(Sin[x]/(1 + Cos[x]^2))*Dt[x] /.
x -> 2*ArcTan[t] /. Dt[t] -> 1],
{t, Limit[Tan[x/2], x -> #1], Infinity}]]& /@ {0, -Pi}
Out[3]=
{{9.297*Second, Pi^2/4},
{9.219*Second, Pi^2/2}}
Peter