Re: Quadratic form: symbolic transformation
- To: mathgroup at smc.vnet.net
- Subject: [mg76807] Re: [mg76801] Quadratic form: symbolic transformation
- From: Fred Simons <f.h.simons at tue.nl>
- Date: Mon, 28 May 2007 00:48:40 -0400 (EDT)
- References: <200705270907.FAA03614@smc.vnet.net>
The function SolveAlways can be used for this purpose, but it delivers
rules in the 'wrong' direction. So we have to manipulate the output of
SolveAlways:
In[1]:= q1 = R*x^2 + S*x + T;
q2 = u*(x + v)^2 + w;
SolveAlways[q1 == q2, x]
Out[3]= {{R -> u, S -> 2*u*v, T -> u*v^2 + w}}
In[4]:= Solve[Apply[Equal, %[[1]], {1}], {u, v, w}]
Out[4]= {{w -> (-S^2 + 4*R*T)/(4*R), u -> R, v -> S/(2*R)}}
Fred Simons
Eindhoven University of Technology
Dr. Wolfgang Hintze wrote:
> Hello,
>
> this is a simple question but perhaps I can get here some information
> towards a more apropriate way of using Mathematica.
>
> I take a very simple example: I would like to write the quadratic form
>
> q1 = R*x^2 + R*x + T
>
> in the form
>
> q2 = u*(x+v)^2 + w
>
> How can I find u, v, and w from R, S, and T?
>
> I'm sure there must be some symbolic way (using a sufficient amount of
> _'s) to answer this question.
>
> My (cumbersome) procedure compares coefficients and looks like this
>
> (* writing down lhs == rhs)
> In[112]:=
> q = R*x^2 + S*x + T == u*(x + v)^2 + w
> Out[112]=
> T + S*x + R*x^2 == w + u*(v + x)^2
>
> (* as q must be an identiy in x, i.e. must hold for all x, I compare
> coefficients at x=0 *)
> In[113]:=
> eq1 = q /. {x -> 0}
> Out[113]=
> T == u*v^2 + w
> In[114]:=
> eq2 = D[q, x] /. {x -> 0}
> Out[114]=
> S == 2*u*v
> In[115]:=
> eq3 = D[q, {x, 2}] /. {x -> 0}
> Out[115]=
> 2*R == 2*u
> In[119]:=
> t = First[Solve[{eq1, eq2, eq3}, {u, v, w}]]
> Out[119]=
> {w -> (-S^2 + 4*R*T)/(4*R), u -> R, v -> S/(2*R)}
>
> (* writing down the result explicitly *)
> In[120]:=
> q /. t
> Out[120]=
> T + S*x + R*x^2 == (-S^2 + 4*R*T)/(4*R) + R*(S/(2*R) + x)^2
> In[122]:=
> Simplify[q /. t]
> Out[122]=
> True
>
> Thanks in advance for any hints.
> Regards,
> Wolfgang
>
>
>
>
- References:
- Quadratic form: symbolic transformation
- From: "Dr. Wolfgang Hintze" <weh@snafu.de>
- Quadratic form: symbolic transformation