Re: Filled Polar plots
- To: mathgroup at smc.vnet.net
- Subject: [mg85180] Re: Filled Polar plots
- From: Yaroslav Bulatov <yaroslavvb at gmail.com>
- Date: Thu, 31 Jan 2008 00:49:49 -0500 (EST)
- References: <fnpnrq$cpt$1@smc.vnet.net>
Thanks for the suggestions, all of them work, ParametricPlot also
works if you use BoundaryStyle -> None, here's the summary
(* Function to Plot *)
f[x_] := (Cos[(3*x)/4]^18 + Sin[(3*x)/4]^18)^(-1/5);
(* Two replacements *)
PolarPlot[f[x], {x, -Pi, Pi}, PlotRange -> All,
Axes -> None] /. {h_Hue,
Line[pp_]} -> {{h, Polygon[pp]}, {Thick, Line[pp]}}
(* One replacement+EdgeForm *)
PolarPlot[f[x], {x, -Pi, Pi}, PlotRange -> All, Axes -> None,
PlotStyle -> Directive[{Lighter[Green, .6], EdgeForm[Gray]}]] /.
Line -> Polygon
(* EdgeForm could be specified in the replacement rule *)
PolarPlot[f[x], {x, -Pi, Pi}, PlotRange -> All, Axes -> None] /.
Line[a_] -> {Yellow, EdgeForm[Thick], Polygon[a]}
(* RegionPlot *)
RegionPlot[f[ArcTan[x, y]] > Sqrt[x^2 + y^2], {x, -4, 4}, {y, -4, 4}]
(* PolarPlot+ParametricPlot *)
Show[ParametricPlot[
f[x] r {Cos[x], Sin[x]} // Evaluate, {r, 0, 1}, {x, -Pi, Pi},
Mesh -> None, PlotPoints -> {3, 50}, PlotStyle -> Green,
BoundaryStyle -> None],
PolarPlot[(formula @@ vals[[1]])[x], {x, -Pi, Pi}], Axes -> False]