Re: Trinomial decics x^10+ax+b = 0; Help with Mathematica
- To: mathgroup at smc.vnet.net
- Subject: [mg93295] Re: [mg93280] Trinomial decics x^10+ax+b = 0; Help with Mathematica
- From: Bob Hanlon <hanlonr at cox.net>
- Date: Mon, 3 Nov 2008 05:25:54 -0500 (EST)
- Reply-to: hanlonr at cox.net
eqns = {-a + m^9 - 8 m^7 n + 21 m^5 n^2 - 20 m^3 n^3 + 5 m n^4 == 0,
-b + m^8 n - 7 m^6 n^2 + 15 m^4 n^3 - 10 m^2 n^4 + n^5 == 0};
R[m_, a_, b_] = Resultant[Sequence @@ First /@ eqns, n]
m^45+246 a m^36-502 b m^35-13606 a^2 m^27+51954 a b m^26-73749 b^2 m^25-245 \
a^3 m^18+135060 a^2 b m^17-92850 a b^2 m^16+383750 b^3 m^15+13605 a^4 \
m^9+27200 a^3 b m^8+25125 a^2 b^2 m^7+12500 a b^3 m^6+3125 b^4 m^5-a^5
For a = 0 and b != 0 there will always be a quintic factor
{R[m, 0, 0], R[m, 0, b]} // Factor
{m^45,m^5 (m^20-625 b m^10+3125 b^2) (m^20+123 b m^10+b^2)}
To test factored polynomials for factors of a specific degree
Clear[FactorQ];
FactorQ[factoredPoly_Times, deg_Integer, m_Symbol] :=
Or @@ (FactorQ[#, deg, m] & /@ (List @@ factoredPoly));
FactorQ[factoredPoly_Power, deg_Integer, m_Symbol] :=
If[factoredPoly === m^deg, True, FactorQ[factoredPoly[[1]], deg, m]];
FactorQ[factoredPoly_, deg_Integer,
m_Symbol] :=
(Length[CoefficientList[factoredPoly, m]] - 1) == deg;
FactorQ[#, 2, x] & /@
{(x + 1) (x + 2), (x + 1)^2 (x + 2), x^2, (x + 1)^2,
x^2 + 1, (x^2 + 1) (x + 2), (x^2 + 1)^3 (x + 2)}
{False,False,True,False,True,True,True}
polys1 = Flatten[
Table[{a, b, Factor[R[m, a, b]]}, {a, -100, -1}, {b, -100, 100}], 1];
ans1 = Select[polys1, FactorQ[#[[3]], 5, m] || FactorQ[#[[3]], 10, m] &]
{}
polys2 = Flatten[
Table[{a, b, Factor[R[m, a, b]]}, {a, 1, 100}, {b, -100, 100}], 1];
ans2 = Select[polys2, FactorQ[#[[3]], 5, m] || FactorQ[#[[3]], 10, m] &]
{}
Not too encouraging for finding other cases.
Bob Hanlon
---- tpiezas at gmail.com wrote:
=============
Hello guys,
I need some help with Mathematica code.
It is easy to eliminate "n" between the two eqn:
-a + m^9 - 8m^7n + 21m^5n^2 - 20m^3n^3 + 5mn^4 = 0
-b + m^8n - 7m^6n^2 + 15m^4n^3 - 10m^2n^4 + n^5 = 0
using the Resultant[] command to find the rather simple 45-deg
polynomial in "m", call it R(m).
As Mathematica runs through integral values of {a,b}, if for some
{a,b} the poly R(m) factors, we are interested in two cases:
Case1: an irreducible decic factor
Case2: an irreducible quintic factor
What is the Mathematica code that tells us what {a,b} gives Case 1 or
Case 2?
Thanks. :-)
Tito
--
Bob Hanlon