Re: How to print TraditionalForm without evaluation
- To: mathgroup at smc.vnet.net
- Subject: [mg92624] Re: [mg92614] How to print TraditionalForm without evaluation
- From: Bob Hanlon <hanlonr at cox.net>
- Date: Thu, 9 Oct 2008 06:33:07 -0400 (EDT)
- Reply-to: hanlonr at cox.net
Recommend that you use columns rather than rows.
input = {
(1 - 3*x^3 + 2*x^5)/(4*x^3),
(-5*x^(1/4) + (x^2)^(4/3))/x^(3/2),
Sin[x], Cos[x]
};
labels = HoldForm[Integrate[#, x]] & /@ input;
output = ReleaseHold[labels] // FullSimplify;
Grid[Transpose[{labels, output}],
Frame -> All,
ItemStyle -> Directive[18, Bold]] // TraditionalForm
Bob Hanlon
---- Serych Jakub <Serych at panska.cz> wrote:
=============
I want to write notebook which prints simple integration examples with
results for the students.
Something like:
ex1 = (1 - 3*x^3 + 2*x^5)/(4*x^3);
ex2 = (-5*x^(1/4) + (x^2)^(4/3))/x^(3/2);
Grid[{
Table[
TraditionalForm[Integrate[Symbol["ex" <> ToString[nr]], x]], {nr, 1, 2}],
(* do not integrate this *)
Table[
TraditionalForm[Integrate[Symbol["ex" <> ToString[nr]], x]], {nr, 1, 2}]},
(* integrate this *)
Frame -> All, ItemStyle -> Directive[FontSize -> 18, Bold]]
(there will be much more examples ex3,ex4, etc.)
This works nice, but I need to tell Mathematica not to Integrate in the first
row of the table - examples (only in the second one - results). Is there any
possibility to suppress the evaluation of the Integral in the first row of
the grid and just print the symbol of Integral and the TraditionalForm of the
example behind it?
May be this is a newbie kind of question, but I have spent lot of time on it,
and I cannot solve it.
Thanks in advance for any help
Jakub
--
Bob Hanlon