Re: Inverse function warnings
- To: mathgroup at smc.vnet.net
- Subject: [mg99237] Re: [mg99164] Inverse function warnings
- From: Bob Hanlon <hanlonr at cox.net>
- Date: Thu, 30 Apr 2009 06:25:23 -0400 (EDT)
- Reply-to: hanlonr at cox.net
eqn = 3^(2 x) - 12 (3^x) + 27 == 0;
Quiet[Solve[eqn, x]]
{{x -> 1}, {x -> 2}}
Off[Solve::ifun]
Solve[eqn, x]
{{x -> 1}, {x -> 2}}
{Reduce[eqn, x, Reals] // ToRules}
{{x -> 1}, {x -> 2}}
{Reduce[{eqn, Element[x, Reals]}, x] // ToRules}
{{x -> 1}, {x -> 2}}
Reduce[eqn, x]
Element[C[1], Integers] &&
(x == 1 + (2*I*Pi*C[1])/Log[3] ||
x == 2 + (2*I*Pi*C[1])/Log[3])
This indicates that there are an infinite number of solutions. For any integer n
Simplify[eqn /. x -> 1 + 2 I*Pi*n/Log[3], Element[n, Integers]]
True
Simplify[eqn /. x -> 2 + 2 I*Pi*n/Log[3], Element[{n}, Integers]]
True
Bob Hanlon
---- davef <davidfrick2003 at yahoo.com> wrote:
=============
When I execute this in Mathematica 7:
Solve[3^(2 x) - 12 (3^x) + 27 == 0, x]
I get this:
Solve::ifun: Inverse functions are being used by Solve, so some solutions may not be found; use Reduce for complete solution information. >>
{{x->1},{x->2}}
1 amd 2 are proper solutions but is it possible to avoid the warning?
If I use Reduce:
Reduce[3^(2 x) - 12 (3^x) + 27 == 0, x]
I get a set of 1 and 2 added to some imaginary number terms that I don't quite understand.
I guess my question is: why would the use of inverse functions be so unreliable a solution as to necessitate a warning? And in the interest of clean output, can the warning be supressed other than by deleteing the cell?
Thanks