Re: How to combine Dynamic graphics in Show?
- To: mathgroup at smc.vnet.net
- Subject: [mg105515] Re: [mg105506] How to combine Dynamic graphics in Show?
- From: Bob Hanlon <hanlonr at cox.net>
- Date: Sun, 6 Dec 2009 01:30:55 -0500 (EST)
- Reply-to: hanlonr at cox.net
Manipulate[
Show[
ListPlot[Range[10]],
Plot[Cos[x], {x, -Pi, Pi}],
PlotRange ->
{{-Pi, Pi}, {-maxy, maxy}}],
{{maxy, 1.1}, 0.1, 4,
ControlType -> VerticalSlider,
ControlPlacement -> Left,
Appearance -> {"LeftArrow"}},
Paneled -> False]
Bob Hanlon
---- "Nasser M. Abbasi" <nma at 12000.org> wrote:
=============
Ver 7.
Hello;
Without the use of DynamicModule[], just some simple code.
I have one Plot and one ListPlot, and I wanted to combine them. Ofcourse I
can use Show[], but when one of the above objects is Dynamics, I can't do
that. I tried many things, and so far, no success.
This is what I have and what I tried:
-------------------
v = VerticalSlider[Dynamic[maxy], {0.1, 4}, Appearance -> "LeftArrow"];
p0 = ListPlot[Range[10]];
p1 = Dynamic[Plot[Cos[x], {x, -Pi, Pi}, PlotRange -> {{-Pi, Pi}, {-maxy,
maxy}}]];
Row[{ver, p1, p0}]
-------------------
The above works, but p1 and p0 are not combined.
But I wanted to combine p1 and p0 into ONE graphics, except now this will
not work as p1 is dynamics. I tried
Row[{ver, Show[p1, p0]}]
Row[{ver, Dynamic@Show[p1, p0]}]
I really thought Dynamic[Show[....]] will do it?
tried few other things....I need to read more about Dynamics, but meanwhile
in case I do not see it, any idea how this can be done?
Notice that p0 is a ListPlot and not a Plot. Else I would have been able to
simply use one Dynamic at Plot[...] to combine the plots and not even need
Show[], like this (assuming the second plot is Cos[x])
v = VerticalSlider[Dynamic[maxy], {0.1, 4}, Appearance -> "LeftArrow"];
p1 = Dynamic[Plot[{Cos[x], Sin[x]}, {x, -Pi, Pi}, PlotRange -> {{-Pi, Pi},
{-maxy, maxy}}]];
Row[{ver, p1}]
and this would have worked.
So, how to combine Dynamic graphics objects?
thanks
--Nasser