Re: Re: LabeledListPlot

• To: mathgroup at smc.vnet.net
• Subject: [mg96346] Re: [mg96315] Re: LabeledListPlot
• From: Bob Hanlon <hanlonr at cox.net>
• Date: Thu, 12 Feb 2009 06:34:29 -0500 (EST)

```data = Sort[RandomReal[{0, 1}, {10, 2}]];

ListPlot[List /@ data,
PlotMarkers -> CharacterRange["a",
FromCharacterCode[96 + Length[data]]],
PlotRange -> {{0, 1}, {0, 1}}]

ListPlot[data,
PlotRange -> {{0, 1}, {0, 1}},
PlotMarkers -> Style[\[EmptyUpTriangle], 36],
Epilog -> (Style[Text[#1[[1]], #1[[2]]], 10, Red] & ) /@
Transpose[{CharacterRange["a",
FromCharacterCode[96 + Length[data]]], data}]]

Bob Hanlon

---- TerryH <tlharter at verizon.net> wrote:

=============
Hi Groupers:
Last November 2008, I posted the inquiry below and one of the
replies that I got was from Jens (also listed below & it worked great).

Now I have a related question, which is:  Instead of labeling the
individual plotted points with an integer, how can you label the
individual plotted points with textual labels?  For example, I want to
label the first plotted point with "a", the second one with "b", the
third with "c", and so on.  I've tried using PlotMarkers but that labels
the entire data set and not individual points.  The best that I could
come up with is to make each x,y pair into its own list, for example
with 3 points to plot (for the illustration here)
data = {{x1,y1},{x2,y2},{x3,y3}}  then feed data[[1]], data[[2]],
data[[3]] into ListPlot, I want to apply the labels {"a","b","c"}.
This works for a Point plotting symbol.  However, it feels cumbersome.

However, I'd really like to use a filled triangle for the plotting
symbol and not the Graphic associated with what
Graphic[Point[{num1,num2}]] gives.  The only way I could get this to
work is to generate 2 separate graphics with one (grfA) have the labels
only, and the other (grfB) without labels but with the correct plotting
symbol, and then bring them together using Show[grfA,grfB].  But this
method really seems ackword, so surely there has to be a better way.
I'm using Ver 6.0.3   Any suggestions?
TIA
.......Terry

Jens-Peer Kuska wrote:
> Hi,
>
> dta = Table[{tmp = Random[], Sin[Pi*tmp]}, {25}] // Sort;
>
> ListPlot[dta] /.
>   Point[lst : {{_, _} ..}] :>
>    MapIndexed[{Text[#2[[1]], #1, {-1, -1}], Point[#1]} &, lst]
>
> Regards
>    Jens
>
> TerryH wrote:
>> Hi Groupers,
>>     In Ver 5.2 and earler there was a function called "LabeledListPlot"
>> In Ver 6.0.1 and 6.0.3 of Mathematica, it seems that this function was
>> inadvertently omitted (Hopefully, it will be included in the next
>> update/Version).  In the meantime does anyone know of a work-around so
>> that one can produce a Labeled?List Plot in Ver 6.0?  TIA
>> .....Terry
>>

```

• Prev by Date: Re: Dynamic changing of variables
• Next by Date: Re: Shortest Path Problem
• Previous by thread: Re: LabeledListPlot
• Next by thread: Re: LabeledListPlot