Mathematica 9 is now available
Services & Resources / Wolfram Forums / MathGroup Archive
-----

MathGroup Archive 2009

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Series expansion of x_n=Tan[x_n]

  • To: mathgroup at smc.vnet.net
  • Subject: [mg95892] Re: Series expansion of x_n=Tan[x_n]
  • From: Scott Hemphill <hemphill at hemphills.net>
  • Date: Thu, 29 Jan 2009 05:55:48 -0500 (EST)
  • References: <glpfin$kot$1@smc.vnet.net>
  • Reply-to: hemphill at alumni.caltech.edu

Francois at news53rd.b1.woo, Fayard at news53rd.b1.woo writes:

> Hello,
>
> I'm new to Mathematica and I want to comptute a series expansion of the
> sequence (x_n) defined by :
>
> x_n=Tan[x_n]    and   n Pi-Pi/2 < x_n < n Pi+Pi/2
>
> It's easy to prove that
>
> x_n = n Pi + O(1)    and   x_n = n Pi + ArcTan[x_n]
>
>>From these 2 formulas, one could easily compte a series expansion of
> (x_n) to any order. For example:
>
> x_n = n Pi + ArcTan[nPi + O(1)] = nPI + Pi/2 -1/(n Pi) + O(1/n^2)
>
> Then we can iterate the Process.
>
> I want to do this whith Mathematica, but I  have a Few Problems :
>  - How can I enter O(1) ? I've tried O(n,Infinity)^0 but it simplifies to=
>  1
>  - When I compute ArcTan[n Pi + Pi/2- 1/(Pi n)+O(1/n)^2), it gives me
> Pi/2-1/(Pi n)+O(1/n)^2. I'm surprised because one could get a better
> serie expansion from that.

I wouldn't try entering O[1] or O[1/n] because I haven't found a
useful interaction between that and Series[].

Your basic iteration can be defined this way:

In[1]:= iter[n_,x_] := n*Pi + ArcTan[x]

In[2]:= iter[n,Infinity]

        Pi
Out[2]= -- + n Pi
        2

This is the series you are looking for, with terms up through the
constant term.


In[3]:= iter[n,%]

                      Pi
Out[3]= n Pi + ArcTan[-- + n Pi]
                      2

In[4]:= Series[%,{n,Infinity,1}]

               Pi    1       1 2
Out[4]= Pi n + -- - ---- + O[-]
               2    Pi n     n

Now this series includes the (1/n) term.


In[5]:= Normal[%]

           1      Pi
Out[5]= -(----) + -- + n Pi
          n Pi    2

In[6]:= iter[n,%]

                       1     Pi
Out[6]= n Pi - ArcTan[---- - -- - n Pi]
                      n Pi   2

In[7]:= Series[%,{n,Infinity,2}]

               Pi    1        1        1 3
Out[7]= Pi n + -- - ---- + ------- + O[-]
               2    Pi n         2     n
                           2 Pi n

Now this series includes the (1/n^2) term.

This whole operation can be put together into one expression:

In[8]:= f[k_] := FixedPoint[Simplify[Series[n*Pi + ArcTan[Normal[#1]], 
        {n, Infinity, k}]] & , Infinity]

In[9]:= f[4]

                                             2         2
               Pi    1        1      8 + 3 Pi    8 + Pi       1 5
Out[9]= Pi n + -- - ---- + ------- - --------- + -------- + O[-]
               2    Pi n         2        3  3       3  4     n
                           2 Pi n    12 Pi  n    8 Pi  n

Scott
-- 
Scott Hemphill	hemphill at alumni.caltech.edu
"This isn't flying.  This is falling, with style."  -- Buzz Lightyear


  • Prev by Date: Re: two y-axes with different scaling
  • Next by Date: Mathematica notebooks don't print or PDF well under Linux
  • Previous by thread: Series expansion of x_n=Tan[x_n]
  • Next by thread: Re: Series expansion of x_n=Tan[x_n]