Services & Resources / Wolfram Forums / MathGroup Archive
-----

MathGroup Archive 2009

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: How to deal with this integral

  • To: mathgroup at smc.vnet.net
  • Subject: [mg97837] Re: How to deal with this integral
  • From: m.r at inbox.ru
  • Date: Mon, 23 Mar 2009 04:03:59 -0500 (EST)
  • References: <gq2eva$edb$1@smc.vnet.net>

paperkite rainyday wrote:
> hi everybody,
>
> I want to deal with this integral with Mathematica:
>
> Integrate[a*b*Exp[-(a+b)]*DiracDelta[1/(4*a)+1/(4*b)+c-t],{a,0,Infinity},{b,0,Infinity},{c,0,Infinity},Assumptions->t>0],
>
> Mathematica 6.0 gives 0. But it is wrong, the correct result is
> (1/2)*x^2*Exp[-x]*((1+x)*BesselK[0,x]+(2+x+2/x)*BesselK[1,x]),
> where x=1/(2*t).
>
> What's wrong?
>
> Thanks,
>
>
> paperkite

It's not as fun when you know the answer, but you can evaluate the
integral by making the change of variables u == a + b, v == a b. The
(u, v) region is given by

In[1]:= Reduce[t > 0 && b > a > 0 && 1/a + 1/b < 4 t && a + b == u &&
a b == v,
 {u, v}, {a, b}, Reals]

Out[1]= t > 0 && u > 1/t && u/(4 t) < v < u^2/4

(we're integrating over b > a, where the substitution function is one-
to-one).

In[2]:= Assuming[t > 0, 2 Integrate[v E^-u/Sqrt[u^2 - 4 v],
     {u, 1/t, Infinity}, {v, u/(4 t), u^2/4}]] /.
  HoldPattern@ MeijerG[{{}, {a_}}, {{b_, c_}, {}}, z_] :>
   z^b E^-z HypergeometricU[a - c, b - c + 1, z] // FullSimplify

Out[2]= (E^(-(1/(2 t))) (BesselK[1, 1/(2 t)] + (1 + 2 t) BesselK[2, 1/
(2 t)]))/(16 t^3)

Maxim Rytin
m.r at inbox.ru


  • Prev by Date: Re: DirectSum (feature request)
  • Next by Date: Re: How do I DistributeDefinitions inside a function?
  • Previous by thread: How to deal with this integral
  • Next by thread: Online Graphic Output