Re: how to show for what values the function is
- To: mathgroup at smc.vnet.net
- Subject: [mg104099] Re: how to show for what values the function is
- From: Bob Hanlon <hanlonr at cox.net>
- Date: Mon, 19 Oct 2009 07:11:51 -0400 (EDT)
- Reply-to: hanlonr at cox.net
f[x_, m_] = m*Log[x]/2^m + (1 - x^m)/(1 + x)^m;
dfdx[x_, m_] = FullSimplify[D[f[x, m], x]];
Plot3D[f[x, m],
{x, 1, 20}, {m, -2, 5},
PlotRange -> {-1/2, 1},
ClippingStyle -> None,
ColorFunction -> Function[{x, m, z},
If[Re[dfdx[x, m]] > 0, Lighter[Blue, .6], Red]],
ColorFunctionScaling -> False,
Mesh -> 10,
PlotPoints -> 75]
Plot3D[{dfdx[x, m], 0},
{x, 1, 20}, {m, -2, 5},
PlotRange -> {-1/16, 1/16},
ClippingStyle -> None,
PlotStyle -> {Automatic,
Directive[Red, Opacity[.75]]}]
ContourPlot[dfdx[x, m],
{x, 1, 20}, {m, -2, 5}]
Bob Hanlon
---- JEZUS <barefoot1980 at gmail.com> wrote:
=============
how to show
that for what values of m, the function
f(x) = m * log(x) / 2^m + (1-x^m) / (1+x)^m
is increasing/decreasing. That for what values of m, df/dx > 0 for all
x>=1, ....
here, x >= 1
it looks like the (i am not sure):
df/dx > 0 for 0 < m <=3
df/dx < 0 for m < 0
df/dx < 0 for m > 0