Re: Faster alternative to AppendTo?
- To: mathgroup at smc.vnet.net
- Subject: [mg102927] Re: [mg102886] Faster alternative to AppendTo?
- From: Bob Hanlon <hanlonr at cox.net>
- Date: Wed, 2 Sep 2009 04:04:37 -0400 (EDT)
- Reply-to: hanlonr at cox.net
g[n_] := If[Mod[n, 2] == 0, n/2, 3 n + 1]
fpl[n_] := FixedPointList[If[EvenQ[#], #/2, 3 # + 1] &, n,
SameTest -> (#2 == 1 &)]
Timing[a = {};
Do[k = m;
orbit = {k};
While[k > 1, AppendTo[orbit, k = g[k]]];
AppendTo[a, orbit];, {m, 2, 25000}]]
{33.9348,Null}
Timing[b = fpl /@ Range[2, 25000];]
{7.86831,Null}
a == b
True
Bob Hanlon
---- Dem_z <dem_z at hotmail.com> wrote:
=============
Hey, sorry I'm really new. I only started using mathematica recently, so I'm not that savvy.
Anyways, I wrote some code to calculate (and store) the orbits around numbers in the Collatz conjecture.
"Take any whole number n greater than 0. If n is even, we halve it (n/2), else we do "triple plus one" and get 3n+1. The conjecture is that for all numbers this process converges to 1. "
http://en.wikipedia.org/wiki/Collatz_conjecture
(*If there's no remainder, divides by 2, else multiply by 3 add 1*)
g[n_] := If[Mod[n, 2] == 0, n/2, 3 n + 1]
(*creates an empty list a. Loops and appends the k's orbit into variable "orbit", which then appends to variable "a" after the While loop is completed. New m, sets new k, which restarts the While loop again.*)
a = {};
Do[
k = m;
orbit = {k};
While[k > 1, AppendTo[orbit, k = g[k]]];
AppendTo[a, orbit];
, {m, 2,1000000}];
Anyways it seems that the AppendTo function gets exponentially slower, as you throw more data into it. Is there a way to make this more efficient? To calculate a million points takes days with this method.