Services & ResourcesWolfram ForumsMathGroup Archive

[Date Index] [Thread Index] [Author Index]

Re: Faster alternative to AppendTo?

• To: mathgroup at smc.vnet.net
• Subject: [mg102915] Re: [mg102886] Faster alternative to AppendTo?
• From: Jaebum Jung <jaebum at wolfram.com>
• Date: Wed, 2 Sep 2009 04:02:27 -0400 (EDT)
• References: <200909010753.DAA18801@smc.vnet.net>

You could rewrite it using NestWhileList and Map; For example,

In[170]:= (a={};
Do[k=m;
orbit={k};
While[k>1,AppendTo[orbit,k=g[k]]];
AppendTo[a,orbit];,{m,2,20000}])//AbsoluteTiming
Out[170]= {15.247986,Null}

In[169]:= (aN=NestWhileList[g,#,#>1&]&/@Range[2,20000];)//AbsoluteTiming
Out[169]= {5.852271,Null}

If you have multi cores, ParallelMap can speed up the computation,

LaunchKernels[]
DistributeDefinitions[g]
In[175]:= Kernels[]//Length
Out[175]= 4

In[168]:= (aP=ParallelMap[NestWhileList[g,#,#>1&]&,Range[2,20000],Method 
-> "CoarsestGrained"];)//AbsoluteTiming
Out[168]= {2.184031,Null}

Check the result:

In[173]:= a===aN===aP
Out[173]= True

- Jaebum

Dem_z wrote:
> Hey, sorry I'm really new. I only started using mathematica recently, so I'm not that savvy.
>
> Anyways, I wrote some code to calculate (and store) the orbits around numbers in the Collatz conjecture.
>
> "Take any whole number n greater than 0. If n is even, we halve it (n/2), else we do "triple plus one" and get 3n+1. The conjecture is that for all numbers this process converges to 1. "
>  http://en.wikipedia.org/wiki/Collatz_conjecture
>
>
> (*If there's no remainder, divides by 2, else multiply by 3 add 1*)
> g[n_] := If[Mod[n, 2] == 0, n/2, 3 n + 1]
>
> (*creates an empty list a. Loops and appends the k's orbit into variable "orbit", which then appends to variable "a" after the While loop is completed.  New m, sets new k, which restarts the While loop again.*)
> a = {};
> Do[
>   k = m;
>   orbit = {k};
>   While[k > 1, AppendTo[orbit, k = g[k]]];
>   AppendTo[a, orbit];
>   , {m, 2,1000000}];
>
> Anyways it seems that the AppendTo function gets exponentially slower, as you throw more data into it. Is there a way to make this more efficient? To calculate a million points takes days with this method.
>
>   

• References:
  • Faster alternative to AppendTo?
    • From: Dem_z <dem_z@hotmail.com>