MathGroup Archive 2009

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Help generalizing Liouville's Polynomial Identity

  • To: mathgroup at smc.vnet.net
  • Subject: [mg103623] Re: Help generalizing Liouville's Polynomial Identity
  • From: pfalloon <pfalloon at gmail.com>
  • Date: Wed, 30 Sep 2009 05:02:34 -0400 (EDT)
  • References: <h9srs3$pc1$1@smc.vnet.net>

On Sep 29, 9:42 pm, TPiezas <tpie... at gmail.com> wrote:
> Hello all,
>
> "Liouville's polynomial identity" is given byhttp://mathworld.wolfram.com=
/LiouvillePolynomialIdentity.htmland can
> be concisely encoded as,
>
> 6(x1^2 + x2^2 + x3^2 + x4^2)^2 = Sum(x_i +/- x_j)^4
>
> To determine the number of terms of the summation, since we are to
> choose 2 objects from 4, then this is Binomial[4,2] = 6. But as there
> are 2 sign changes, then total is 2 x 6 = 12 terms, given explicitly
> in the link above.  Going higher, and choosing 3 objects out of n
> variables, I found that,
>
> 60(x1^2 + x2^2 + ... + x7^2)^2 = Sum(x_i +/- x_j +/- x_k)^4
>
> is true. The RHS contains 4 x 35 = 140 terms. (If the x_i are non-
> zero, one cannot express the square of the sum of less than 7 squares
> in a similar manner.)
>
> Question: If we take the next step,
>
> a(x1^2 + x2^2 + ... + x_n^2)^2 = Sum(x_i +/- x_j +/- x_k +/- x_m)^4
>
> for some positive integer "a", then what is the least n, if we are to
> choose 4 objects at a time out of the x_n?
>
> I believe the RHS is a simple matter for Mathematica to calculate, and
> one can incrementally test n = 5,6,7,...etc until a neat identity is
> found.
>
> - Titus

Hi,

The following Mathematica implementation may be useful:

First, define functions to generate the lhs (without multiplicative
constant) and rhs of the putative identity, for n terms and subsets of
length k (n=4,k=2 in the original identity):

(* left side with n terms *)
lhs[n_] := Sum[x[i]^2, {i,n}]^2

(* right side with n terms, subsets of length k *)
rhs[n_,k_] := Module[{sets, terms},

	(* get all distinct subsets with k elements *)
	sets = Subsets[Array[x,n], {k}];

	(* get all sums involving +/- over each subset (with first term
always positive) *)
	terms = Table[Tuples[Join[{{First@set}}, Table[{-t,t},
{t,Rest@set}]]], {set, sets}] // Flatten[#,1] &;

	(* take sum^4 *)
	Total[(Plus@@@terms)^4]
]


Search for values of n,k where the ratio of rhs/lhs is a numeric
quantity:

res = Do[expr = FullSimplify[rhs[n,k]/lhs[n]];
	If[NumericQ[expr], Sow[{n,k,expr}]],
	{n,4,10},
	{k,2,n}
] // Reap // Last // Flatten[#,1]&

{{{4, 2, 6}, {7, 3, 60}, {10, 4, 672}}}


I believe this is *all* the values for which such an identity holds
for n<=10, 2<=k<=n. Note there are the two solutions you mentioned
together with another one for n=10, k=4.

Assuming the identity exists, the constant needed on the lhs can
actually be found just by looking at the coefficient of, say, x[1]^4.
On the lhs it is the constant, while on the rhs it is given by:

multiplier[n_,k_] := 2^(k-1) Binomial[n-1,k-1]

This is because there are Binomial[n-1,k-1] subsets of length k which
contain x[1], and for each subset there are 2^(k-1) possible
combinations of +/- signs. Check that this holds:

multiplier@@@res[[All,;;-2]] == res[[All,-1]]

True


Hope this helps!

Cheers,
Peter.



  • Prev by Date: Re: Help generalizing Liouville's Polynomial Identity
  • Next by Date: Re: Histogram
  • Previous by thread: Re: Help generalizing Liouville's Polynomial Identity
  • Next by thread: Paper heading