MathGroup Archive 2010

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: CONDITION/DATA ANALYSIS/PLOTS

  • To: mathgroup at smc.vnet.net
  • Subject: [mg107840] Re: CONDITION/DATA ANALYSIS/PLOTS
  • From: Bob Hanlon <hanlonr at cox.net>
  • Date: Sun, 28 Feb 2010 04:53:33 -0500 (EST)
  • Reply-to: hanlonr at cox.net

data = RandomReal[{0, .125}, 25];

plotData = SplitBy[
    data /. x_?(# > .1 &) -> Null,
    NumericQ] /.
   {Null, ___} -> Sequence[];

nColumns = 2;

Grid[Partition[Join[
   ListLinePlot[#,
      Frame -> True, Axes -> False,
      ImageSize -> 256,
      PlotRange -> {-0.005, 0.105},
      PlotMarkers -> {Automatic, 8}] & /@
    plotData,
   Table["", {nColumns - 1}]],
  nColumns]]


Bob Hanlon

---- jihane <jihane.ajaja at mail.mcgill.ca> wrote: 

=============
I am currently having trouble achieving something on mathematica and I would greatly appreciate your help.
My problem is the following: 

I want to construct a loop that will read data and when data<0.1, put it data in a list and do so until data>0.1. the problem is the data fluctuates and i have kind of sinusoidals if i plot the raw data.What I want to do is ask the program to start puting the data<0.1 in a list until data>0.1 and then stop, then plot the data. Then the list would be reinitialized and the program would start from where it stopped and when it reaches values of data<0.1 start putting the data in the list again and stop again when data>0.1 and plot the data and so on so forth. I would then have plots of each kind of sinusoidals individually and not all of them together in one plot as i did previously.

Thank you very much




  • Prev by Date: Re: Using tilde in symbol name
  • Next by Date: Re: auto-save in Mathematica
  • Previous by thread: CONDITION/DATA ANALYSIS/PLOTS
  • Next by thread: Parametrized assumptions