       Re: to get all parametric plots/line traces

• To: mathgroup at smc.vnet.net
• Subject: [mg114270] Re: to get all parametric plots/line traces
• From: Bob Hanlon <hanlonr at cox.net>
• Date: Mon, 29 Nov 2010 06:09:06 -0500 (EST)

```Manipulate[ContourPlot[
Evaluate[Table[
(1 - lam) (x^2 + y^2 - x y - 1) + lam (x^2 + y^2 + x y - 1) == 0,
{lam, -2, 2, N[d]}]],
{x, -2, 2}, {y, -2, 2},
GridLines -> Automatic,
Mesh -> {200, 200}],
{{d, 1/2, "step size for lam"}, {1/4, 1/3, 1/2, 1}}]

Manipulate[del = N[d];
Manipulate[
ContourPlot3D[
(1 - lam) (x^2 + y^2 - x y - 1) + lam (x^2 + y^2 + x y - 1) == 0,
{x, -2, 2}, {y, -2, 2}, {lam, -2, lamMax},
AxesLabel -> {"x", "y", "lam"},
PlotRange ->
{{-2.05, 2.05}, {-2.05, 2.05}, {-2.05, 2.05}}],
{{lamMax, 0}, -2 + del, 2, del, Appearance -> "Labeled"},
Paneled -> False],
{{d, 1/2, "step size for lam"}, {1/4, 1/3, 1/2, 1}}]

Bob Hanlon

---- Narasimham <mathma18 at hotmail.com> wrote:

=============
How to get plot of family of curves, instead of being able to view
only one plot a at any point of time?

Animate[ContourPlot[(1 - lam) (x^2 + y^2 - x y - 1) +     lam (x^2 +
y^2 + x  y - 1) == 0,
{x, -2, 2},  {y, -2, 2}, GridLines -> Automatic, Mesh -> {200, 200}],
{lam, -2, 2, .25}]

```

• Prev by Date: Re: Why does this pattern fail to match?
• Next by Date: Re: to get all parametric plots/line traces
• Previous by thread: Re: to get all parametric plots/line traces
• Next by thread: Re: to get all parametric plots/line traces