Services & Resources / Wolfram Forums / MathGroup Archive
-----

MathGroup Archive 2010

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Solving a non-linear system to find coefficients in

  • To: mathgroup at smc.vnet.net
  • Subject: [mg113016] Re: Solving a non-linear system to find coefficients in
  • From: Bob Hanlon <hanlonr at cox.net>
  • Date: Mon, 11 Oct 2010 05:16:01 -0400 (EDT)

Needs["NumericalDifferentialEquationAnalysis`"]

sys = RungeKuttaOrderConditions[4, 4,
     ButcherRowSum -> True,
     RungeKuttaMethod -> Explicit] /.
    {c[2] -> 1/2, 
     a[3, 1] -> 0} // Flatten;

SplitBy[soln = Reduce[sys] // ToRules // Sort, Head[#[[1]]] &]

{{a[2, 1] -> 1/2, a[3, 2] -> 1/2, a[4, 1] -> 0, a[4, 2] -> 0, 
  a[4, 3] -> 1}, 
   {b[1] -> 1/6, b[2] -> 1/3, b[3] -> 1/3, b[4] -> 1/6}, 
   {c[3] -> 1/2, c[4] -> 1}}

And @@ (sys /. soln)

True


Bob Hanlon

---- Allamarein <matteo.diplomacy at gmail.com> wrote: 

=============
I have just launched:

RungeKuttaOrderConditions[4, 4, ButcherRowSum -> True,
RungeKuttaMethod -> Explicit]

Well done: I get a set of  11 non-linear equations with 13 unknows,
like theory predicts.
I can choice c(2) = 1/2 and a(3,1) = 0, so I have 11 eqs. and 11unkns.
Anyway, how can I solve this system in Mathematica? I need to find the
elements of matrix a and of vector b and c.

This is only an example.
If I could solve the previous problem, I would extend that procedure
to RK6 or RK8



  • Prev by Date: Nested list - adding to each entry
  • Next by Date: Re: Shading in Plot3D
  • Previous by thread: Re: Nested list - adding to each entry
  • Next by thread: Efficient Histogram Algorithm?