Mathematica 9 is now available
Services & Resources / Wolfram Forums / MathGroup Archive
-----

MathGroup Archive 2010

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Poisson's integral formula doesn't work

  • To: mathgroup at smc.vnet.net
  • Subject: [mg112790] Re: Poisson's integral formula doesn't work
  • From: Mark McClure <mcmcclur at unca.edu>
  • Date: Thu, 30 Sep 2010 04:53:33 -0400 (EDT)
  • References: <201009290813.EAA27997@smc.vnet.net>

On Wed, Sep 29, 2010 at 4:13 AM, Sam Takoy <sam.takoy at yahoo.com> wrote:

> Poisson's integral formula provides a solution to the Laplace equation
> on the unit circle with Dirichlet boundary conditions.

Almost certainly a branch cut issue.  You can use the periodicity of
the cosine to avoid the branch cut like so:

Integrate[Cos[phi] (1 - r^2)/(1 + r^2 - 2 r*Cos[theta - phi]),
  {phi, theta - Pi, theta + Pi},
Assumptions -> {0 < r < 1, -Pi < theta < Pi}]/(2 Pi)


I wonder exactly what you want to do ultimately.  It frequently makes
sense to do this kind of thing numerically.  For example, you could
define u as follows:

Clear[u];
u[r_?NumericQ, theta_?NumericQ] :=
 NIntegrate[Cos[phi] (1 - r^2)/(1 + r^2 - 2 r*Cos[theta - phi]),
   {phi, -\[Pi], \[Pi]}]/(2 Pi)

While it works only with specific numerical values, you can treat u as
a function in just about every way.  For example, you can plot its
values on a circle near the boundary to illustrate that you should
recover the cosine:

Plot[u[0.99, theta], {theta, -Pi, Pi}]

You can plot it over the disk, for that matter:

ParametricPlot3D[{r*Cos[theta], r*Sin[theta], u[r, theta]},
 {r, 0, 0.99}, {theta, -Pi, Pi}]


Mark McClure


  • Prev by Date: How to unflatten an array ?
  • Next by Date: Re: calculate vertex of a parabola
  • Previous by thread: Poisson's integral formula doesn't work
  • Next by thread: Multiline functions