Re: Ploting a transformation of a set
- To: mathgroup at smc.vnet.net
- Subject: [mg123343] Re: Ploting a transformation of a set
- From: Bob Hanlon <hanlonr357 at gmail.com>
- Date: Fri, 2 Dec 2011 07:21:33 -0500 (EST)
- Delivered-to: l-mathgroup@mail-archive0.wolfram.com
- References: <201111300819.DAA17061@smc.vnet.net>
For some reason this isn't working the way it was earlier on my
system. The sliders are showing up as input boxes.
This works properly:
Manipulate[
Module[{
aps = AbsolutePointSize[4]},
Row[{
RegionPlot[x + y < 2 && 0 < x < 2 && 0 < y < 2,
{x, 0, 2}, {y, 0, 2},
ImageSize -> 200,
Epilog -> {Red, aps, Point[{h, v}]}],
RegionPlot[t, {xp, 0, 2}, {yp, 0, 2},
ImageSize -> 200,
Epilog -> {Red, aps,
Point[{Sqrt[h + v/2], Sqrt[v + h/2]}]}]}]],
{{h, .5, "x"}, 0, 2, .01, Appearance -> "Labeled"},
{{v, .5, "y"}, 0, 2, .01, Appearance -> "Labeled"}]
Bob Hanlon
On Thu, Dec 1, 2011 at 5:53 AM, Bob Hanlon <hanlonr357 at gmail.com> wrote:
> t = (x + y < 2 && 0 < x < 2 && 0 < y < 2) /.
> Solve[{xp == Sqrt[x + y/2], yp == Sqrt[y + x/2]},
> {x, y}][[1]] // Simplify
>
> xp^2 + yp^2 < 3 && 0 < 2*xp^2 - yp^2 < 3 && -3 < xp^2 - 2*yp^2 < 0
>
> Manipulate[
> Module[{
> aps = AbsolutePointSize[4],
> ap = (Appearance -> "Labeled")},
> Row[{
> RegionPlot[x + y < 2 && 0 < x < 2 && 0 < y < 2,
> {x, 0, 2}, {y, 0, 2},
> ImageSize -> 200,
> Epilog -> {Red, aps, Point[{h, v}]}],
> RegionPlot[t, {xp, 0, 2}, {yp, 0, 2},
> ImageSize -> 200,
> Epilog -> {Red, aps,
> Point[{Sqrt[h + v/2], Sqrt[v + h/2]}]}]}]],
> {{h, .5, "x"}, 0, 2, .01, ap},
> {{v, .5, "y"}, 0, 2, .01, ap}]
>
>
> Bob Hanlon
>
> On Wed, Nov 30, 2011 at 3:19 AM, Justin <justin.valasek at gmail.com> wrote:
>> Hello,
>> I would like to plot the following transformation of the set {x,y; x+y<2=
& x>0 & y> 0} => {(x+.5y)^.5, (y+.5x)^.5}.
>> Is there any way to do this in mathematica?
>> thanks
>>