MathGroup Archive 2011

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: How to make the same two expressions

  • To: mathgroup at smc.vnet.net
  • Subject: [mg119586] Re: How to make the same two expressions
  • From: Bob Hanlon <hanlonr at cox.net>
  • Date: Sat, 11 Jun 2011 03:58:52 -0400 (EDT)
  • Reply-to: hanlonr at cox.net

expr1 = Rationalize[-1.0019 - 
    1. Log[0.00190438 - 
       0.0249519 b] + (0.000040093 a Log[0.152644/(0.152644 + 2 b)])/b, 0];

expr2 = Rationalize[-1.00004 - 
    1. Log[0.0000378969 - 
       0.0249519 b] + (0.000040093 a Log[0.0030376/(0.0030376 + 2 b)])/b, 0];

eqn = expr1 == expr2 // Simplify;

Find instances that satisfy the equation

soln = FindInstance[eqn, {a, b}, Reals, 4];

And @@ (eqn /. soln // Simplify)

True

soln // N

{{a -> 250.968, b -> 0.000993046}, {a -> 253.051, 
  b -> 0.00100671}, {a -> 83.7737, b -> -0.000955844}, {a -> 294.505, 
  b -> 0.00122536}}

Pick a value for a and solve for b

FindRoot[eqn /. a -> 200, {b, 0.001}]

{b -> 0.000568337}

Reduce[eqn /. a -> 200, b, Reals] // N // ToRules

{b -> 0.000568337}

Solve[eqn /. a -> 200, b, Reals] // N

{{b -> 0.000568337}}

Or pick a value for b and solve for a

FindRoot[eqn /. b -> 10^-3, {a, 200}]

{a -> 252.023}

Reduce[eqn /. b -> 10^-3, a, Reals] // N // ToRules

{a -> 252.023}

Solve[eqn /. b -> 10^-3, a, Reals] // N

{{a -> 252.023}}


Bob Hanlon

---- Mariano Pierantozzi <mariano.pierantozzi at gmail.com> wrote: 

=============
Hi everyone,
i've this problem with Mathemtica:
i've got 2 expression depending on a and b:
expr1= -1.0019 - 1. Log[0.00190438 - 0.0249519 b] + (0.000040093 a
Log[0.152644/(0.152644 + 2 b)])/b
expr2=-1.00004 - 1. Log[0.0000378969 - 0.0249519 b] + (0.000040093 a
Log[0.0030376/(0.0030376 + 2 b)])/b
I want to make the same this two expressions.
The problem is that if i try to solve this is one equation in two parameter:
a and b.
So i think to put inside some value of a and b so i make equal the two
expression less than 10^-12 (for example)
I've to do a list of value:
b can vary beetwen -0.0015188 < b < 0.0015188 (the domain of logarithmic
function) and a must vary for example  -2000 to 2000.
I can not find a waydo it. I try with list, and put the value inside, but
i've some problem.
if anyone can help I would be grateful...
Thank you!

Mariano Pierantozzi
PhD student




  • Prev by Date: Re: Seaching in Pi a sequence. Looking for a faster method
  • Next by Date: Re: Front end - Error when saving file
  • Previous by thread: Re: How to make the same two expressions
  • Next by thread: Re: How to make the same two expressions