Re: get a, b from numbers in the form a+b Pi
- To: mathgroup at smc.vnet.net
- Subject: [mg119138] Re: get a, b from numbers in the form a+b Pi
- From: Bob Hanlon <hanlonr at cox.net>
- Date: Mon, 23 May 2011 06:22:58 -0400 (EDT)
nums = {1/2 (-2 + Pi), -2 + (3 Pi)/4, -(11/3) + (5 Pi)/4,
5/48 (-64 + 21 Pi), -(61/5) + (63 Pi)/16, -(338/15) + (231 Pi)/32};
nums /. {Plus -> List, Pi -> 1}
{{-1, 1/2}, {-2, 3/4}, {-(11/3), 5/4}, {-(20/3), 35/16}, {-(61/5),
63/16},
{-(338/15), 231/32}}
(List @@@ Expand[nums]) /. Pi -> 1
{{-1, 1/2}, {-2, 3/4}, {-(11/3), 5/4}, {-(20/3), 35/16}, {-(61/5),
63/16},
{-(338/15), 231/32}}
{#[[1]], #[[2]]/Pi} & /@ Expand[nums]
{{-1, 1/2}, {-2, 3/4}, {-(11/3), 5/4}, {-(20/3), 35/16}, {-(61/5),
63/16},
{-(338/15), 231/32}}
#/{1, Pi} & /@ (List @@@ Expand[nums])
{{-1, 1/2}, {-2, 3/4}, {-(11/3), 5/4}, {-(20/3), 35/16}, {-(61/5),
63/16},
{-(338/15), 231/32}}
% == %% == %%% == %%%%
True
Bob Hanlon
---- "1.156" <rob at piovere.com> wrote:
=============
I have lists of numbers (Mathematica output) all numerically in the
form a + b*Pi and I'm trying to extract the values of a and b for
further work.
Here's an example of the best I've been able to do so far:
nums={1/2 (-2+\[Pi]),-2+(3 \[Pi])/4,-(11/3)+(5 \[Pi])/4,5/48 (-64+21
\[Pi]),-(61/5)+(63 \[Pi])/16,-(338/15)+(231 \[Pi])/32};
{FullForm[#][[1,1]],FullForm[#][[1,2]]/\[Pi]}&/@nums
When I run this line of code 4 of the six input numbers give me the
{a,b} I'm looking for but the first and fourth entries fail because the
form isn't right. Possibly I could patch this scheme to look for a small
finite set of possibilities of input number form but I suspect I may a
long way from attacking this problem correctly.
Can someone offer some other ideas on how to pull this off? Many thanks
for looking at this. Rob
--
Sent from my plain desktop PC.