       Re: What inspite FindInstance

• To: mathgroup at smc.vnet.net
• Subject: [mg122744] Re: What inspite FindInstance
• From: Andrzej Kozlowski <akoz at mimuw.edu.pl>
• Date: Wed, 9 Nov 2011 06:25:05 -0500 (EST)
• Delivered-to: l-mathgroup@mail-archive0.wolfram.com
• References: <201111081215.HAA04920@smc.vnet.net>

```On 8 Nov 2011, at 13:15, Artur wrote:

> Dear Mathematica Gurus,
> Matematical problem is following: find pair of integres {d,x} which fill
> equation (d ^2 +
>      270 d Root[1 - 270 #1^3 - 5832 #1^5 + 3645 #1^6 &, 1]^3 -
>      2916 x Root[1 - 270 #1^3 - 5832 #1^5 + 3645 #1^6 &, 1]^5 +
>      3645 Root[1 - 270 #1^3 - 5832 #1^5 + 3645 #1^6 &, 1]^6 ==
>     0)
>
> FindInstance[(d ^2 +
>      270 d Root[1 - 270 #1^3 - 5832 #1^5 + 3645 #1^6 &, 1]^3 -
>      2916 x Root[1 - 270 #1^3 - 5832 #1^5 + 3645 #1^6 &, 1]^5 +
>      3645 Root[1 - 270 #1^3 - 5832 #1^5 + 3645 #1^6 &, 1]^6 ==
>     0) && (x d != 0), {x, d}, Integers]
>
> Mathematica report:
> FindInstance::nsmet: The methods available to FindInstance are
> insufficient to find the requested instances or prove they do not exist. >>
>
> First solution is x=2 and d=-1
> I'm looking for next ones. Who have idea what to do?
>
> Best wishes
> Artur
>
>

x=2, d= -1

Checking:

pp = d^2 + 270 d Root[1 - 270 #1^3 - 5832 #1^5 + 3645 #1^6 &, 1]^3 -
2916 x Root[1 - 270 #1^3 - 5832 #1^5 + 3645 #1^6 &, 1]^5 +
3645 Root[1 - 270 #1^3 - 5832 #1^5 + 3645 #1^6 &, 1]^6;

FullSimplify[pp /. {d -> -1, x -> 2}]

0

How did I find it? Well, let

w = Root[3645*#1^6 - 5832*#1^5 - 270*#1^3 + 1 & , 1];

Then w has to be a root of

In:= ff = pp /. w -> z

Out= d^2+270 d z^3-2916 x z^5+3645 z^6

On the other hand,

In:= gg = MinimalPolynomial[w, z]

Out= 3645 z^6-5832 z^5-270 z^3+1

Hence ff has to divide gg. Now

In:= PolynomialQuotientRemainder[ff, gg, z]

Out= {1,d^2+(270 d+270) z^3+(5832-2916 x) z^5-1}

And from this we see that d= -1 and x = 2.

Andrzej Kozlowski

```

• Prev by Date: Plot the results of Findroot
• Next by Date: Re: Import files on accessible URL and save in
• Previous by thread: What inspite FindInstance
• Next by thread: Re: What inspite FindInstance