Re: help with double integration
- To: mathgroup at smc.vnet.net
- Subject: [mg121777] Re: help with double integration
- From: Peter Pein <petsie at dordos.net>
- Date: Sat, 1 Oct 2011 03:09:15 -0400 (EDT)
- Delivered-to: l-mathgroup@mail-archive0.wolfram.com
- References: <j63t52$6dv$1@smc.vnet.net>
Am 30.09.2011 10:03, schrieb Salman Durrani:
> Hello
>
> I am trying to use mathematica to do the following double integration:
>
> Integrate[
> Integrate[
> r^2*ArcCos[x/r] - x*Sqrt[r^2 - x^2], {x, Sqrt[3] y,
> Sqrt[r^2 - y^2]}], {y, 0, r/2}]
>
> The correct answer is:
> r^4(pi^2/144 + pi/(24Sqrt{3}) - 1/32)
>
> However I am unable to get mathematica to produce the correct result. I have tried splitting into two integrations and using the assumptions option (suggested by newsgroup):
>
> Integrate[
> r^2*ArcCos[x/r] - x*Sqrt[r^2 - x^2], {x, Sqrt[3] y,
> Sqrt[r^2 - y^2]}, Assumptions -> {y > 0, r > 2 y}] // Simplify
>
> The above produces the result for the inner integration but then
>
> Integrate[
> y^3/3 + 2/3 r^2 Sqrt[r^2 - 3 y^2] + y^2 Sqrt[r^2 - 3 y^2] -
> r^2 y (1 + Sqrt[3] ArcCos[(Sqrt[3] y)/r]) +
> r^2 Sqrt[r^2 - y^2] ArcSec[r/Sqrt[r^2 - y^2]], {y, 0,
> r/2}] // Simplify
>
> does not produce any result.
>
> Am I missing something fundamental here. Any help would be appreciated.
>
> Thanks
>
> Kahless
>
Hi,
if you express ArcCos in terms of Log it works well:
In[1]:= Integrate[TrigToExp[r^2*ArcCos[x/r] - x*Sqrt[r^2 - x^2]], {y, 0,
r/2}, {x, Sqrt[3]*y, Sqrt[r^2 - y^2]}, Assumptions -> r > 2*y > 0]
Out[1]= (1/288)*(-9 + 4*Sqrt[3]*Pi + 2*Pi^2)*r^4
and
In[2]:= Expand[(1/288)*(-9 + 4*Sqrt[3]*Pi + 2*Pi^2)*r^4 -
r^4*(Pi^2/144 + Pi/(24*Sqrt[3]) - 1/32)]
Out[2]= 0
shows that this is the expected result.
hth,
Peter