Mathematica 9 is now available
Services & Resources / Wolfram Forums / MathGroup Archive
-----

MathGroup Archive 2011

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Problem in "block cutting"

  • To: mathgroup at smc.vnet.net
  • Subject: [mg121590] Re: Problem in "block cutting"
  • From: Heike Gramberg <heike.gramberg at gmail.com>
  • Date: Wed, 21 Sep 2011 05:34:02 -0400 (EDT)
  • Delivered-to: l-mathgroup@mail-archive0.wolfram.com
  • References: <201109201008.GAA00710@smc.vnet.net>

Since Cosh[p]^2-Sinh[p]^2==1 for all p, x0 and z0 satisfy the equation

(((z0 + 0.075) 1.25 + 3)/2)^2 - (x0 1.25 1.2)^2 ==1

Therefore you could do something like

Module[{x, y, z},
 Show[RegionPlot3D[(((y + 0.075) 1.25 + 3)/2)^2 - (x 1.25 1.2)^2 <= 1, 
     ##, Boxed -> False, Axes -> True, 
     TextureCoordinateFunction -> ({2 #1 + #2, #2 + #3} &),
     Mesh -> None, 
     PlotStyle -> 
      Directive[Brown, Specularity[White, 50], 
       Texture[ExampleData[{"ColorTexture", "BurlOak"}]]], 
     Lighting -> "Neutral",
     AxesLabel -> {"x", "y", "z"}] & @@@ {{{x, 0, 1}, {y, -1, 0}, {z, 
      0, 1}},
    {{x, 0, 1}, {y, -1, 0}, {z, -1, 0}},
    {{x, -1, 0}, {y, -1, 0}, {z, 0, 1}},
    {{x, -1, 0}, {y, -1, 0}, {z, -1, 0}}}, PlotRange -> All, 
  Axes -> False, BoxRatios -> {2, 1, 2}]]

Heike.

On 20 Sep 2011, at 12:08, Roger Bagula wrote:

> In architecture there is a curve called an hanging chain curve
> that is based on Sinh and Cosh functions.
> I want to cut an arch made of a cylinder of the hanging chain
> from a rectangular set of cubic blocks.
> I have it visualized but not actualized in Mathematica:
> 
> x0 = (Sinh[p]/1.2)/1.25;
> y0 = Sin[t];
> z0 = (2*Cosh[p] - 3)/1.25 - 0.075;
> gc = ParametricPlot3D[{x0, z0, y0}, {t, -Pi, Pi}, {p, -1, 1},
>  Boxed -> False, Axes -> True,
>  TextureCoordinateFunction -> ({2 #4, #5} &),
>  PlotStyle ->
>   Directive[Brown, Specularity[White, 50],
>    Texture[ExampleData[{"ColorTexture", "BurlOak"}]]],
>  Lighting -> "Neutral"]
> g1 = Show[
>  Graphics3D[{Opacity[0.5], Cuboid[{0, -1, 0}], Cuboid[{-1, -1, 0}],
>    Cuboid[{-1, -1, -1}], Cuboid[{0, -1, -1}]}], Boxed -> False]
> Show[{gc, g1}, PlotRange -> All]
> 
> Something like the RegionFunction:
> 
> ga = SphericalPlot3D[
>  1 + Sin[3 \[Theta]] Sin[3 \[Phi]]/3, {\[Theta], 0, Pi}, {\[Phi], 0,
>   2 Pi}, RegionFunction -> (#6 > 0.95 &),
>  PlotStyle -> FaceForm[Blue, Cyan], Boxed -> False, Axes -> False,
>  Mesh -> False]
> 
> Would seem to be a way to approach the problem,
> but I can't figure out how.
> Roger Bagula
> 





  • Prev by Date: Re: List Manipulation- Advanced beginner question
  • Next by Date: Re: Plot axis length and size ratio (TwoPlot revive)
  • Previous by thread: Problem in "block cutting"
  • Next by thread: Re: Problem in "block cutting"