MathGroup Archive 2012

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Ambiguity of "Plot"

  • To: mathgroup at smc.vnet.net
  • Subject: [mg127806] Re: Ambiguity of "Plot"
  • From: Bob Hanlon <hanlonr357 at gmail.com>
  • Date: Thu, 23 Aug 2012 20:48:54 -0400 (EDT)
  • Delivered-to: l-mathgroup@mail-archive0.wolfram.com
  • Delivered-to: l-mathgroup@wolfram.com
  • Delivered-to: mathgroup-newout@smc.vnet.net
  • Delivered-to: mathgroup-newsend@smc.vnet.net
  • References: <20120823065423.92A8A6844@smc.vnet.net>

Clear[f, \[Alpha], \[Rho], \[Delta]]

f[\[Alpha]_, \[Rho]_, \[Delta]_] =
  (\[Rho] + \[Delta] - \[Delta] \[Alpha] -
      Sqrt[\[Delta] \[Rho] \[Alpha] (1 - \[Alpha]) + \[Rho]^2 \
\[Alpha]])/
    ((\[Rho] + \[Delta]) (1 - \[Alpha])) // Simplify;

Assuming[{\[Rho] > 0},
 Limit[f[\[Alpha], \[Rho], \[Delta]], \[Alpha] -> 1]]

1/2

Series[f[\[Alpha], \[Rho], \[Delta]], {\[Alpha], 1, 0}] //

  Simplify[#, {\[Rho] > 0}] & // Normal

1/2

f[\[Alpha], \[Rho], 0] // Simplify[#, {\[Rho] > 0}] &

1/(1 + Sqrt[\[Alpha]])

% /. \[Alpha] -> 1

1/2

f[\[Alpha], 0, \[Delta]]

1

Manipulate[
 Column[{
   Plot[f[\[Alpha], \[Rho], \[Delta]], {\[Alpha], 0, 1},
    PlotRange -> {0, 1},
    AxesLabel -> {"\[Alpha]", "f"},
    ImageSize -> 300],
   Plot3D[
    f[\[Alpha], \[Rho]1, \[Delta]], {\[Alpha], 0, 1}, {\[Rho]1, 0.001,
      1},
    PlotRange -> {0, 1},
    AxesLabel -> {"\n\[Alpha]", "\n   \[Rho]", "f     "},
    ImageSize -> 300],
   Plot3D[
    f[\[Alpha], \[Rho], \[Delta]1], {\[Alpha], 0, 1}, {\[Delta]1,
     0, .5},
    PlotRange -> {0, 1},
    AxesLabel -> {"\n\[Alpha]", "   \[Delta]", "f     "},
    ImageSize -> 300]}],
 {\[Rho], 0.001, 1, Appearance -> "Labeled"},
 {\[Delta], 0, .5, Appearance -> "Labeled"}]


Bob Hanlon


On Thu, Aug 23, 2012 at 2:54 AM,  <JikaiRF at aol.com> wrote:
> Dear members;
>
> I have been embarrassed about a function Plot.
> I would like to plot a curve defined as follows:
>
>  f(\[Alpha]) = (\[Rho] + \[Delta] - \[Delta] \[Alpha] - Sqrt[\[Delta] \[Rho] \
> \[Alpha] (1 - \[Alpha]) + \[Rho]^2 \[Alpha]])/((\[Rho] + \[Delta]) (1 \
> - \[Alpha])).
> Here, 0 < \[Alpha] < 1.
>
> And I programmed in this way;
> Plot[f(\[Alpha]), { \[Alpha],  0 < \[Alpha] < 1}]
>
> The curve I obtained from Mathematica is monotonously decreasing. AS a result, f(1) =0.
> However, by using  l'H=F4pital7 theorem, f(1) = 1/2 is correct.
> In this situation, I would like to obtain an accurate curve.
>
>    Sincerely,
> Fujio Takata
> Kobe University, Japan.
> I use Mathematica 8.040, Macintosh version.
>
>



  • Prev by Date: Re: Non-sequential composition of pure functions
  • Next by Date: Re: Drawing a Line From One Plot to Another
  • Previous by thread: Ambiguity of "Plot"
  • Next by thread: Re: Ambiguity of "Plot"