Mathematica 9 is now available
Services & Resources / Wolfram Forums / MathGroup Archive
-----

MathGroup Archive 2012

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Something other than PlotStyle to change look of graphs

  • To: mathgroup at smc.vnet.net
  • Subject: [mg124864] Re: Something other than PlotStyle to change look of graphs
  • From: Chris Young <cy56 at comcast.net>
  • Date: Fri, 10 Feb 2012 05:51:10 -0500 (EST)
  • Delivered-to: l-mathgroup@mail-archive0.wolfram.com
  • References: <jgtil7$67p$1@smc.vnet.net>

I'm still working out the details here, but here's a more general
approach to using plot legends via Legend[ ]:


fncs[x_] := {
  SurvivalFunction[WeibullDistribution[2.2, 3.2], x],
  SurvivalFunction[LogNormalDistribution[0.1, 0.8], x],
  SurvivalFunction[ExponentialDistribution[0.6], x]
  }

plotStyles = {
  {Black, Thickness[Small]},
  {Dashing[Tiny], Black},
  {Dashing[Large], Black, Thickness[Large]}
  }

plotNames = {"Weibull", "LogNormal", "Exponential"}


GraphicsRow[
 {
  Show[
   Plot[
    fncs[x] // Evaluate,
    {x, 0, 5},
    PlotStyle -> plotStyles
    ],

   ListPlot[
    Transpose[Table[fncs[x], {x, 1, 5}]],
    PlotMarkers -> Automatic,
    Axes -> True
    ],

   PlotLabel -> Style["Survival Curves", FontSize -> 12],
   AxesLabel -> TraditionalForm /@ {"t", "S(t)"}
   ],

  Graphics @
   Legend[
    Table[
     {
      Graphics @ Append[plotStyles[[i]], Line[{{0, 0}, {2, 0}}]],
      plotNames[[i]]
      },
     {i, 1, 3}
     ],

    LegendPosition -> {0.3, -0.1},
    LegendTextSpace -> 1,
    LegendSize -> {0.25, 0.25},
    LegendOrientation -> Vertical,
    LegendBackground -> LightYellow,
    ShadowBackground -> LightOrange
    ]
  }
 ]

On 2012-02-08 10:26:47 +0000, cylurian said:

> I have three functions in one plot.  I'm using PlotStyle to
> differentiate the graphs, but I need more options.  I need each graph
> to have some special marker, like a diamond, circle, etc.  I'm using
> Mathematica 8 and I'm also using PlotLegend.  Any suggestions?
>
> My code is:
>
> Plot[{SurvivalFunction[WeibullDistribution[2.2, 3.2], x],
>   SurvivalFunction[LogNormalDistribution[.1, .8], x],
>   SurvivalFunction[ExponentialDistribution[.6], x]}, {x, 0, 5},
>  PlotStyle -> {{ Black, Thickness[Small]}, {Dashing[Tiny],
>     Black}, {Dashing[Large], Black, Thickness[Large]}},
>  AxesLabel -> TraditionalForm /@ {t, "S(t)"}, Ticks -> None,
>  DisplayFunction -> Identity,
>  PlotLabel -> Style["Survival Curves", FontSize -> 18],
>  PlotLegend -> {"Weibull", "LogNormal", "Exponential"},
>  LegendPosition -> {.3, -0.1}, LegendTextSpace -> 4,
>  LegendLabelSpace -> .5, LegendLabel -> "Survival Curves",
>  LegendOrientation -> Vertical, LegendBackground -> White,
>  LegendSize -> .4, ShadowBackground -> White]





  • Prev by Date: Re: How to call 'Clear' from within a function?
  • Next by Date: Abort computation on any message
  • Previous by thread: Re: Something other than PlotStyle to change look of graphs
  • Next by thread: Kolmogorov Smirnov in two or more dimensions